*temp wreckage false
*temp enfilade_fight false
*temp pierced false
*temp ae 2
*temp jokinground false
*temp wyrdbat true
*temp stillnodes false
*temp treatment 1
*temp ohgodarmour false
*temp jumpahead 0

Before we get started, would you like to play through the game normally, or skip ahead?

Note that skipping ahead will result in slightly lower stats and make it a little more difficult to maximise personality, relationships, and some hidden values. However, you should still be able to pass most checks.

You will be presented with a brief series of questions to set your key decisions.
*choice
    #Play normally.
        *goto startingscene
    #Skip to Chapter 2. [MC's past.]
        *set jumpahead 1
        *label ch2
        *set rel_wyrd +5
        *set rel_architect +5
        *set livingconditions 2
        *set arcade true
        *set surpasshere true
        *set met_wa true
        
        Do you lean more expressive, or more reserved?
        *choice
            #Expressive.
                *set expressive 70
                *goto im
            #Reserved.
                *set expressive 30
                *goto im
            #Balanced.
                *goto im
                
        *label im
        How about instinctive vs. methodical?  
        *choice
            #Instinctive.
                *set instinctive 70
                *goto fs
            #Methodical.
                *set instinctive 30
                *goto fs
            #Balanced.
                *goto fs
           
        *label fs
        What fighting style do you favour?
        *choice
            #Hand-to-hand.
                *set fighting_style 1
                *goto ps
            #Adaptable improvising.
                *set fighting_style 2
                *goto ps
            #Wielding my powers.
                *set fighting_style 3
                *goto ps
       
        *label ps
        What is your power speciality? 
        *choice
            #Nodes.
                *set speciality 1
                *set snick "Creepy"
                *goto sf
            #Mutations.
                *set speciality 2
                *set snick "Chompy"
                *goto sf
            #Carapace.
                *set speciality 3
                *set snick "Shelly"
                *goto sf
                
        *label sf
        How did the fight with Surpass go?
        *choice
            #I pretty much got my ass kicked.
                *set surpass_fight 3
                *if jumpahead = 1
                    *set mc_health 3
                *goto mcl
            #It wasn't great.
                *set surpass_fight 1
                *goto mcl
            #We fought to a draw.
                *set surpass_fight 2
                *goto mcl
                
        *label mcl
        What motive have you claimed?
        *choice
            #Taking down the system.
                *set motive 1
                *goto ht
            #Sticking it to the heroes.
                *set motive 2
                *goto ht
            #Money.
                *set motive 3
                *goto ht
            #I refused to give a motive.
                *set motive 4
                *goto ht

        *label ht
        How tall are you?
        *choice
            #Very short.
                *set mc_height 2
                *set subterfuge +2
                *set guts -2
                
            #Short.
                *set mc_height 3
                *set subterfuge +1
                *set guts -1
            #Average.
                *set mc_height 4
            #Tall.
                *set mc_height 5
                *set guts +1
                *set subterfuge -1
            #Very tall.
                *set mc_height 6
                *set subterfuge -2
                *set guts +2
                
        *if jumpahead = 1
            You're all set!
            
            *page_break Proceed to Chapter 2.
            *goto_scene new_origin
        *else
            *goto ch3
    #Skip to Chapter 3. [Meeting the Altruists for the first time.]
        *set jumpahead 2
        *goto ch2
    #Skip to Chapter 4. [Returning to the Coven, meeting Alistair.]
        *set jumpahead 3
        *goto ch2
    #Skip to Chapter 5. [The WPP job, reporting to CG.]
        *set jumpahead 4
        *goto ch2
    #Skip to Chapter 6. [Venturing into the Zone.]
        *set jumpahead 5
        *goto ch2
    #Skip to Chapter 7. [Masquerade.]
        *set jumpahead 6
        *goto ch2
    #Skip to Chapter 8. [At the café with Alistair/CG.]
        *set jumpahead 7
        *goto ch2
    #Skip to Chapter 9. [Hounds HQ.]
        *set jumpahead 8
        *goto ch2
    #Skip to Chapter 10. [The Coven meeting.]
        *set jumpahead 9
        *goto ch2
    #Skip to Chapter 11. [New Altruists mission.]
        *set jumpahead 10
        *goto ch2
    
*label ch3
*set adventure true
*set prologue true
*set met_coven false
*set met_cg false
*set opening false
*set rogueperiod 2
How would you like to set your appearance?
*choice
            #Manually.
                Your eyes are:
                *choice
                    #Brown.
                       *set mc_eyes 2
                       *set mc_oeyes 2
                       *goto skincustom
                    #Blue.
                        *set mc_eyes 3
                        *set mc_oeyes 3
                        *goto skincustom
                    #Green.
                        *set mc_eyes 4
                        *set mc_oeyes 4
                        *goto skincustom
                    #Hazel.
                        *set mc_eyes 5
                        *set mc_oeyes 5
                        *goto skincustom
                    #Grey.
                        *set mc_oeyes 6
                        *set mc_eyes 6
                        *goto skincustom
            #Preset.
                *set mc_eyes 2
                *set mc_oeyes 2
                *set grammarmatters 3
                *set skindetail 3
                *set mc_skintone 4
                *set mc_hair 2
                *set mc_ohair 2
                *set mc_hairtype 3
                *set mc_hairlength 5
                *set mc_build 4
                *set mc_exbuild 4
                *set rogueand 4
                *set rogueperiod 2
                *set appearancedelay false

                *goto pcname
            
*label skincustom
*set grammarmatters 2
*set appearancedelay false
Your skin is:
*choice
    #Very dark.
        *set mc_skintone 2
        *goto skindetail
    #Dark.
        *set mc_skintone 3
        *goto skindetail
    #Light brown.
        *set mc_skintone 4
        *goto skindetail
    #Tan.
        *set mc_skintone 5
        *goto skindetail
    #Fair.
        *set mc_skintone 6
        *goto skindetail
    #Very pale.
        *set mc_skintone 7
        *goto skindetail

*label skindetail
*set grammarmatters 3
*set skindetail 2
Your skin is @{mc_skintone |very dark|dark|light brown|tan|light|pale} and…
*choice
    #Freckled.
        *set skindetail 3
        *goto haircustom
    #Weathered.
        *set skindetail 4
        *goto haircustom
    #Pockmarked.
        *set skindetail 5
        *goto haircustom
    #Smooth.
        *set skindetail 6
        *goto haircustom

*label haircustom
Your hair is:
*choice
    #Dark brown.
        *set mc_hair 2
        *set mc_ohair 2
        *goto hairtype
    #Medium brown.
        *set mc_hair 3
        *set mc_ohair 3
        *goto hairtype
    #Light brown.
        *set mc_hair 4
        *set mc_ohair 4
        *goto hairtype
    #Blonde.
        *set mc_hair 5
        *set mc_ohair 5
        *goto hairtype
    #Dirty blonde.
        *set mc_hair 6
        *set mc_ohair 6
        *goto hairtype
    #Auburn.
        *set mc_hair 7
        *set mc_ohair 7
        *goto hairtype
    #Red.
        *set mc_hair 8
        *set mc_ohair 8
        *goto hairtype
    #Black.
        *set mc_hair 9
        *set mc_ohair 9
        *goto hairtype

*label hairtype
*set rogueand 2
*choice
    #Straight.
        *set mc_hairtype 2
        *goto hairlength
    #Wavy.
        *set mc_hairtype 3
        *goto hairlength
    #Curly.
        *set mc_hairtype 4
        *goto hairlength
    #Natural.
        *set mc_hairtype 5
        *set natural true
        *goto hairlength
    #Textured.
        *set mc_hairtype 6
        *set natural true
        *goto hairlength
*label hairlength
*set rogueand 3
*set mc_hairlength 2
and…
*choice
    #Very short.
        *set mc_hairlength 3
        *goto pcname
    #Cropped.
        *set mc_hairlength 4
        *goto pcname
    #Ear length.
        *set mc_hairlength 5
        *goto pcname
    #Chin length.
        *set mc_hairlength 6
        *goto pcname
    #Shoulder length.
        *set mc_hairlength 7
        *goto pcname
    #Very long.
        *set mc_hairlength 8
        *goto pcname
    
    
*label pcname
*set rogueperiod 2
*set mc_exbuild 4
*set mc_build 7
Your name is…
*choice
    #Morgan
        *set forename "Morgan"
        *goto nickname
    #Yolanda
        *set forename "Yolanda"
        *goto nickname
    #Elizabeth
        *set forename "Elizabeth"
        *set bethfactor true
        *goto nickname
    #Tristan
        *set forename "Tristan"
        *goto nickname
    #[Input my own name]
        *input_text forename
        *goto nickname
    
*label nickname
And…
*choice
    #My nickname is...
        *input_text mc_name
        *set nickname true
        *goto surname
    #I don't have a nickname.
        *set mc_name forename
        *goto surname
    
*label surname
Your surname is:
*choice
    #MacReady
        *set surname "MacReady"
        *set fullname (forename&" ")&surname
        *goto surnameconfirm
    #Fletcher
        *set surname "Fletcher"
        *set fullname (forename&" ")&surname
        *goto surnameconfirm
    #Hart
        *set surname "Hart"
        *set fullname (forename&" ")&surname
        *goto surnameconfirm
    #Lake
        *set surname "Lake"
        *set fullname (forename&" ")&surname
        *goto surnameconfirm
    #[Input my own surname]
        *input_text surname
        *set fullname (forename&" ")&surname
        *goto surnameconfirm
    
*label surnameconfirm
Your pronouns are:
*choice
    #He/him.
        *set mc_he "he"
        *set mc_him "him"
        *set mc_his "his"
        *set mc_singular true
        *goto confirmpronouns
    #She/her.
        *set mc_he "she"
        *set mc_him "her"
        *set mc_his "her"
        *set mc_singular true
        *goto confirmpronouns
    #They/them
        *set mc_he "they"
        *set mc_him "them"
        *set mc_his "their"
        *set mc_singular false
        *goto confirmpronouns
    #[Input my own.]
        Please enter your subjective pronoun (for example, he, she, they).
        *input_text mc_he
        Please enter your objective pronoun (for example, him, her, them).
        *input_text mc_him
        Please enter your possessive pronoun (for example his, her, their).
        *input_text mc_his
        Do your pronouns work best with singular or plural verbs?
        *choice
          #Singular (for example "he says", "she says").
              *set mc_singular true
              *goto confirmpronouns
          #Plural (for example "they say".)
              *set mc_singular false
              *goto confirmpronouns

*label confirmpronouns

Your pronouns are ${mc_he}/${mc_him}, as in: ${mc_he} walk@{mc_singular s|} down the street, watching out for ${mc_his} friends to catch up to ${mc_him}.

Is that right?
*choice
    #Yes.
        *goto genderselect
    *if (not (choice_randomtest)) #No.
        *goto surnameconfirm

*label genderselect

As for your gender…
*choice
    #I'm male.
        *set mc_gender "male"
        *set compatible_teddie true
        *set compatible_beth false
        *set cis true
        *goto gendercomplete
    #I'm male, though that's something I figured out for myself.
        *set mc_gender "male"
        *set compatible_teddie true
        *set compatible_beth false
        *goto gendercomplete
    #I'm female.
        *set mc_gender "female"
        *set cis true
        *set compatible_beth true
        *goto gendercomplete
    #I'm female, though that's something I figured out for myself.
        *set mc_gender "female"
        *set compatible_beth true
    #I'm nonbinary.
        *set mc_gender "nonbinary"
        *goto gendercomplete
    #I'm nonbinary and consider myself transmasc.
        *set mc_gender "nonbinary"
        *set compatible_teddie true
        *set compatible_beth false
    #I'm nonbinary and consider myself transfemme.
        *set mc_gender "nonbinary"
        *set compatible_beth true
    #[Input my own gender]
        *input_text mc_gender
        *goto gendercomplete

*label gendercomplete
Also…
*choice
    #I use masculine-leaning terms. [man, boy, mister]
        *set mc_boy "boy"
        *set mc_guy "guy"
        *set mc_man "man"
        *set mc_king "king"
        *set mc_malsir "sir"
        *set mc_malprince "prince"
        *set mc_sibling "brother"
        *set mc_child "son"
        *set mc_boyfriend "boyfriend"
    #I use feminine-leaning terms. [woman, girl, miss]
        *set mc_boy "girl"
        *set mc_guy "gal"
        *set mc_man "woman"
        *set mc_king "queen"
        *set mc_malsir "ma'am"
        *set mc_malprince "princess"
        *set mc_sibling "sister"
        *set mc_child "daughter"
        *set mc_boyfriend "girlfriend"
    #I use neutral terms. [person, kid, mx]
        *set mc_boy "kid"
        *set mc_guy "person"
        *set mc_man "person"
        *set mc_king "monarch"
        *set mc_malsir "boss"
        *set mc_malprince "princex"
        *set mc_sibling "sibling"
        *set mc_child "child"
        *set mc_boyfriend "datefriend"
        
My best skill is:
*choice
    #Guts.
        *set guts +20
        *set funspeciality 2
        *goto skill2
    #Observation.
        *set observation +20
        *set funspeciality 3 
        *goto skill2
    #Knowledge.
        *set knowledge +20
        *set funspeciality 4
        *goto skill2
    #Subterfuge.
        *set subterfuge +20
        *set funspeciality 5
        *goto skill2
    
*label skill2
My weak skill is:
*choice
    *selectable_if ((guts < 50) and (mc_build != 6)) #Guts.
        *set guts -20
        *goto fg
    *selectable_if (observation < 50) #Observation.
        *set observation -20
        *goto fg
    *selectable_if (knowledge < 50) #Knowledge.
        *set knowledge -20
        *goto fg
    *selectable_if (subterfuge < 50) #Subterfuge.
        *set subterfuge -20
        *goto fg
 
*label fg
Regarding my friendships with the AdVenture group:
*choice
    #Beth is my best friend.
        *set bestie 1
        *goto sexuality
    *selectable_if (compatible_beth) #I'm dating Beth.
        *set dated_beth true
        *set prev_li "Beth"
        *set dating true
        *set bestie 1
        *goto sexuality
    #Prii is my best friend.
        *set bestie 2
        *goto sexuality
    #I'm dating Prii.
        *set dated_prii true
        *set prev_li "Prii"
        *set dating true
        *set bestie 2
        *goto sexuality
    #Shauna is my best friend.
        *set bestie 3
        *goto sexuality
    #I'm dating Shauna.
        *set dated_shauna true
        *set prev_li "Shauna"
        *set dating true
        *set bestie 3
        *goto sexuality
    #Grant is my best friend.
        *set bestie 4
        *goto sexuality
    #I'm dating Grant.
        *set dated_grant true
        *set prev_li "Grant"
        *set dating true
        *set bestie 4
        *goto sexuality
    
*label sexuality
With regards to physical and romantic relationships:
*choice
    *selectable_if (not (dating)) #I'm interested in neither. (Ace/Aromantic)
        *set aro 4
        *set ace true
        *goto os
    *selectable_if (not (dating)) #I don't want romance, but I don't mind having fun. (Aromantic)
        Specifically:
        *choice
            #I'd be open to sleeping with somebody else.
                *set aro 2
                *goto os
            #I like to kiss and be physically affectionate, but no more.
                *set aro 3
                *goto os
            #I like to flirt, but nothing more than that.
                *set aro 3
                *set touchingokay false
                *goto os
    #Romantic relationships are fine, but I don't want to get physically intimate. (Asexual)
        *set ace true
        Specifically:
        *choice
            #Affectionate touching such as holding hands is alright.
                *goto  os
            #I don't like to be touched in general.
                *set touchingokay false
                *goto os
    #I'm comfortable with both.
        *goto os
    
*label os
*set priip true
*set bethp true
What was the ultimate outcome of your encounter with the creature under the building?
*choice
    #I helped Beth and Shauna escape, but was left behind.
        *set origin 6
        *set alive 2
        *set priistatus 2
        *set bethstatus 2
        *set grantstatus 2
        *set shaunastatus 3
    #I helped Beth and Grant escape, but was left behind.
        *set origin 2
        *set priistatus 3
        *set bethstatus 2
        *set grantstatus 3
        *set shaunastatus 4
    #I fled, abandoning my friends.
        *set origin 1
        *set ranaway true
        *set guilt 1
    #I first ran, and then tried to return, but didn't make it.
        *set origin 3
        *set ranaway true
        *set guilt 3
    #I fought as hard as I could, standing against the odds.
        *set origin 4
        *set priistatus 2
        *set shaunastatus 2
        *set bethstatus 2
        *set grantstatus 3
    #I tried to fight, but was easily overcome.
        *set origin 5
        *set priistatus 2
        *set shaunastatus 2
        *set bethstatus 2
        *set grantstatus 3
    #I fought, but ran away after Prii and Shauna were killed.
        *set origin 3
        *set priistatus 3
        *set shaunastatus 4
        *set bethstatus 2
        *set grantstatus 3

*if (ranaway)
    What do you feel about that night now?
    *choice
        #Guilt for running away.
            *set guilt 1
        #Resolved. I had to run. It was life or death.
            *set guilt 2
        #Insecurity. I tell myself I made the right choice by running, but...
            *set guilt 3

*else
    What's your attitude towards Beth, after everything?
    *choice
        #Understanding.
            *set battitude 1
        #Resentful.
            *set battitude 2
        #Utterly numb.
            *set battitude 3
        #Grief-stricken. Bereft.
            *set battitude 4
        #Furious.
            *set battitude 5
            
*set namedisplay 3
*set prologue false
*set met_coven true
*set met_cg true
*if guts < 18
    *set guts 0
*else
    *set guts -18
*set knowledge -10
*set observation - 6
*set subterfuge - 7

*if jumpahead = 2
    You're all set!
    *page_break Proceed to Chapter 3.
    *goto_scene recruiting

*else
    *goto ch4

*label ch4
*set dime true
*set met_ktg true
*set rel_architect +5
*set rel_wyrd + 5
*set mc_build 7
*set specialdesc 1
*set appearancestatus 2
*set wyrdisplay 2
*set archdisplay 2
*set walkfeel 1
*set juice 100

What kind of relationship do you have with CG, your handler?
*choice
    #She wants the best for me.
        *set rel_cg +4
    #She's the closest thing I have to a friend.
        *set rel_cg +7
    #I can't stand her.
        *set rel_cg -7
        *set cg_dislike true
        
What alteration has the Juice made to your physical appearance?
*choice
    #My hair is bleached white.
        *set feature 1
        *set feathair true
        *set mc_hair 10
    #My eyes are pale and washed out.
        *set feature 2
        *set feateyes true
        *set mc_eyes 7
    #Black veins criss-crossing my shoulders.
        *set feature 3
        *set featdetail 2
    #Mawlike markings on my abdomen.
        *set feature 4
        *set featdetail 3
        
Choose a skill to work on.
*choice
    #Guts
        *set guts +5
    #Knowledge
        *set knowledge +5
    #Observation
        *set observation +5
    #Subterfuge
        *set subterfuge +5

Did you take the mystery pasta?
*choice
    #Yes.
        *set pasta true
    #No.
        *set pasta false
        
What did you think of the Department of Parahuman Relations, before it all?
*choice
    #I distrusted them.
        *set dpr 1
    #I felt they had an impossible task.
        *set dpr 2
    #I was indifferent.
        *set dpr 3
    #Screw them, and the rest of the government too.
        *set dpr 4
        
Are you using your real name with Dion, Mallory, and the others?

*choice
    #Yes.
        *set pseudonym false
        *set namedisplay 4
        *set aka mc_name
        
        *if (nickname)
            *set aka2 forename
            
        *else
            *set aka2 mc_name
        *goto nameselection
    *if (not(choice_randomtest)) #No.
        *set pseudonym true
        *input_text aka
        *goto nmechk
        
*label nmechk
*set pseudonym true
*if ((aka = forename) or (aka = mc_name))
    That's… your real name.
    *page_break Oh, right.
    *input_text aka
    *goto nmechk
*elseif ((aka = "Dime") or (aka = "Paradigm"))
    There's no world in which that is a good idea.
    *page_break Think of something else.
    *input_text aka
    *goto nmechk
*elseif (((aka = "Prii") or (aka = "Grant")) or (aka = "Shauna"))
    *label dothat
    You couldn't possibly do that to $!{aka}.
    *page_break Think of something else.
    *input_text aka
    *goto nmechk
*elseif (aka = "Beth")
    *if (nickname_salt > 0)
        That name's tainted now.
        *page_break Think of something else.
        *input_text aka
        *goto nmechk
    *elseif (ranaway) or (battitude = 1)
        *goto dothat
        
    *else
        *if (battitude = 2) or (battitude > 3)
            Do you really want to name yourself after someone you're so messed up over?
            *goto mny
            
        *elseif (battitude = 3)
            Despite your usual numbness towards Beth, the idea of taking on her name sends a distinct feeling of discomfort through you.
            
            *label mny
            *page_break Maybe not.
            *input_text aka
            *goto nmechk
                   
*else
    You're going with the alias $!{aka}, right?
    *choice
        #Yes.
            *set aka2 aka
            *goto nameselection
        *if (not(choice_randomtest)) #Actually, it's...
            *input_text aka
            *goto nmechk
        
*label nameselection
What name have you chosen for your superpowered identity?
*choice
    #Thorn.
        *set mask "thorn"
        *goto nameconfirmation
    #Thresh.
        *set mask "thresh"
        *goto nameconfirmation
    #Manticore.
        *set mask "manticore"
        *goto nameconfirmation
    #Chironex.
        *set mask "chironex"
        *goto nameconfirmation
    #Paradigm.
        *set mask "paradigm"
        *goto nameconfirmation
    *if (not(choice_randomtest)) #[Input my own name]
        *input_text mask
        *goto mynameis

*label mynameis
*if (((mask = "Hypothesis") or (mask = "Catalyst")) or (mask = "Coven"))

    That's… an incredibly bad idea.
    
    Yeah, no. You're going to need to pick something else. You don't have a death wish.
    *page_break Reconsider.
    *goto nameselection

*elseif (((mask = "Surpass") or (mask = "Arcade")) or (mask = "Enfilade"))
    
    Funny, but also the kind of thing that gets you onto the heroes' shitlists.
    
    *page_break Reconsider.
    *goto nameselection

*elseif ((mask = "Wyrd") or (mask = "Architect"))

    Nope, pick again.
    *input_text mask
    *goto nameselection

*else
    *goto nameconfirmation


*label nameconfirmation
You'll be going by $!{mask}, correct?
*choice
    #Yes.
        *set masknamed true
        
        *if ((mask = "dime") or (mask = "paradigm"))
            *set diming true
            
        *goto namechosen
    #No.
        You tell them:
        *input_text mask
        *goto mynameis
    
*label namechosen
*if (dating)
    Are you still struggling to process the loss of your partner?
    *choice
        #Yes.
            *set brokenheart bestie
        #No.
            *set brokenheart 5
            
Wil's full name is…
*choice
    #Wilson (male)
        *set wname "Wilson"
        *set wgender "male"
        *set whe "he"
        *set whim "him"
        *set whis "his"
        *set wboy "boy"
        *set wman "man"
        *set wboyfriend "boyfriend"
    #Wilma (female)
        *set wname "Wilma"
        *set wgender "female"
        *set whe "she"
        *set whim "her"
        *set whis "her"
        *set wboy "girl"
        *set wman "woman"
        *set wboyfriend "girlfriend"
    #Willow (nonbinary)
        *set wname "Willow"
        *set wgender "nonbinary"
        *set whe "xe"
        *set whim "xem"
        *set whis "xer"
        *set wboy "kid"
        *set wman "person"
        *set wboyfriend "datefriend"
        
How did your first meeting with ${wname}, Kay, and Teddie go, in general?
*choice
    #I think it went pretty well.
        *set wimpression 1
        *set rel_wil +7
        *set rel_kay +5
        *set rel_teddie +5
    #I kept to myself.
        *set wimpression 3
        *set rel_wil +5
        *set rel_teddie +5
        *set rel_kay +5
    #I clashed with Wil and Teddie.
        *set wimpression 2
        *set antagonise true
        *set rel_wil -3
        *set rel_teddie -3
        
Who did you give your phone number?
*choice
    #Wil.
        *set rel_wil +5
        *set telephone 3
    #Kay.
        *set rel_kay +3
        *set rel_teddie +3
        *set telephone 2
    #Teddie.
        *set rel_kay +3
        *set rel_teddie +3
        *set telephone 1

*if aro != 4
    Are you developing a romantic or physical interest in anyone?
    *choice
        #Mallory.
            *set interest_wyrd true
            *set flirt_wyrd +1
        #Wil.
            *set interest_wil true
            *set flirt_wil +1
        #Kay.
            *set interest_kay true
            *set flirt_kay +1
        *selectable_if (compatible_teddie) #Teddie.
            *set interest_teddie true
            *set flirt_teddie +1
        #Nobody in particular.
            *goto prevailatt
            
*label prevailatt            
*if (jumpahead = 3)
    What's your prevailing attitude towards your current circumstances?
    *choice
        #Resentment.
            *set seethe +5
        #Resignation.
            *set break +5
        #Professionalism.
            *set loyal +5
            
    You're all set!
    *page_break Proceed to Chapter 4.
    *goto_scene intro_coven_real
*else
    *set covendisplay true
    *set teamdisplay 2
    *set vials +1
    *set met_alistair true
    *set alidisplay 3
    *set juice - 10
    *set rel_architect %+ 5
    *set rel_wyrd %+ 5
    *set rel_teddie %+ 5
    *set rel_wil %+ 5
    *set rel_kay %+ 5
    How did you react to Catalyst's attack?
    *choice
        #I endured, hiding my hatred.
            *set coven_history 3
            *set defiance 3
        #I flinched and cowered.
            *set coven_history 1
            *set defiance 0
        #I lowered my head in deference.
            *set coven_history 2
            *set defiance 2
            
    What's your opinion of Variable, AKA Airy?
    *choice
        #They're a pain in the butt.
            *set ariattitude 1
        #A face in the crowd.
            *set ariattitude 2
        #In the orbit of a friend.
            *set ariattitude 3
        *selectable_if (coven_history = 3) #A useful tool.
            *set ariattitude 4
            
    How'd things go with CG while at the Coven HQ?
    *choice
        #It was fine.
            *set rel_cg + 5
        #We argued.
            *set cgannoy true
            *set rel_cg -5
        *if (aro != 4) #I think I'm developing feelings for her.
            *set interest_cg true
            *set flirt_cg +1
            
            *if cg_dislike
                *set t_cg true
                
            *set rel_cg +5
            
    What's your attitude towards Catalyst at the moment?
    *choice
        #He's not worth it.
            *set rel_catalyst 10
        #I'll get him back someday.
            *set cattitude 2
            *if defiance < 3
                *set defiance +1
        #I'm going to fucking kill him.
            *set cattitude 3
            *if defiance < 3
                *set defiance +2
                
    So, how about Alistair, the mystery deliverer of pasta?
    *choice
        #I told him to leave at earliest opportunity.
            *set rel_alistair 15
            *set aliscram true
            *goto ferret
        #We talked a bit, but I wouldn't tell him my name.
            *set rel_alistair 30
            *set doubt_alistair +5
        #Not only did we talk, I told him my name.
            *set rel_alistair 40
            *if (not (pseudonym))
                *set doubt_alistair + 20
                
    And did you keep his phone number?
    *choice
        #Yes
            *set alinumber 2
        #No
            *set alinumber 3
       
    *label ferret
    Did you ferret any interesting information out of Architect?
    *choice
        #Yes, the dynamic between him and Wyrd.
            *set doubt_architect +10
            *set archease 1
        #Yes, how well-connected he is.
            *set doubt_architect +10
            *set archconnections 1
        #No.
            *set doubt_architect 0
            
    Ahead of your first mission with the Altruists, what's your perspective on killing?
    *choice
        #To be avoided as best I can.
            *set killthink 1
        #If some people die, that's the way it is.
            *set killthink 2
        #I have no compunctions about it whatsoever.
            *set killthink 3
            
    *if (jumpahead = 4)
        You're all set!
        *page_break Proceed to Chapter 5.
        *goto_scene firstcaper

    *else
        *set patrol 2
        *set patrolstatus 2
        *set sexualitytalk_teddie true
        *set juice - 15
        
        How effectively did you handle the Wesson Parks Patrol?
        *choice
            #Very.
                *set wpp 1
            #Middling.
                *set wpp 2
            #It was almost a disaster.
                *set wpp 3
                
        Did you stop to help them after the fact?
        *choice
            #Yes.
                *set grey 1
                *set justification 4
            #Nope.
                *set grey 0
                
        What kind of introduction did you give?  
        *choice
            #Straight to the point.
                *set introtype 1
            #Bombastic.
                *set introtype 2
            *selectable_if (grey = 0) #I made an example of Ranger.
                *set brutal + 3
                *set psycho +1
                *set introtype 3
                *set rangerhurt 3
                *if motive = 1
                    *set justification 1
                    
                *elseif ((motive = 2) or (motive = 3))
                    *set justification 3
                 
                *else
                    *set justification 2
            *selectable_if (speciality = 2) #I showed off how scary my powers are.
                *set introtype 4
                
        Did Teddie get infuriated by your tactics, causing him to storm off after an argument?
        *choice
            #Yes.
                *set sackkay true
                *set rel_teddie -25
                *set po_teddie true
                *set romance_teddie 1
            #No.
                *set rel_teddie +5
           
        *temp activities 0
        What did you get up to during your downtime?
        
        *label activities
        *choice
            *disable_reuse #I worked on my physical state, restoring Guts.
                *set gutsrestore true
                *set guts + 9
            *disable_reuse #I got reconnected, restoring Knowledge.
                *set knowledgerestore true
                *set knowledge + 10
            *disable_reuse #I untrained my instinct to ignore things, restoring Observation.
                *set observationrestore true
                *set observation +6
            *disable_reuse #I practiced my quiet movements, restoring Subterfuge.
                *set subterfugerestore true
                *set subterfuge +7
            *disable_reuse #Honestly, I just spent some time looking after myself.
                *set tidy true
            *disable_reuse #I tried to find out more information regarding what happened to my friends and I.
                *set searched true
            *disable_reuse #I continued the investigation into Architect and Wyrd.
                *set archinfo +1
                *set archpath 1
            
        *set activities +1
        *if activities = 1
            Also…
            *goto activities
        *else
            *if (interest_wil)
                Are any sparks flying between you and Wil?
                *if aro = 3
                    *choice
                        #Nope.
                            *set rel_wil +1
                        #We agreed to some casual flirtation.
                            *set romance_wil 2
                            *set rel_wil %+ 20
                *elseif brokenheart < 5
                    *choice
                        #Nope.
                            *set rel_wil +1
                        #I'd like there to be, but it's hard to get over $!{prev_li}.
                            *set romance_wil 3
                            *set rel_wil %+ 20
                *else
                    *choice
                        #Nope.
                            *set rel_wil +1
                        #Uh... feels like we're still figuring things out.
                            *set romance_wil 5
                            *set rel_wil %+ 20
                        #Yes!
                            *set romance_wil 4
                            *set rel_wil %+ 20
                            
                    *goto ttcgs  
                            
            *else
                *goto ttcgs
            
*label ttcgs
Did you talk to CG? Like, properly talk to her?
*choice
    #Yes.
        *set rel_cg %+ 20
        *set connectcg true
    #No.
        *set rel_cg - 5
        
And how did you handle reporting about the Altruists' upcoming Zone venture?
*choice
    #I told her, because it's my mission.
        *set inform1 1
        *set defiance -1
        *label ttz
        *set trust_cg +1
        *set covenstr +1
        *set doubt_hypothesis -10
    #I told her, because I'll just get caught if I lie.
        *set inform1 2
        *goto ttz
    #I told her to gain more trust from the Coven.
        *set inform1 3
        *set defiance +1
        *goto ttz
    #I told her because I didn't want to screw her over.
        *set inform1 4
        *goto ttz
    #I didn't tell her: I'm starting to fight back.
        *set inform1 5
        *set defiance +2
    #I didn't tell her: I don't want to screw my new team over.
        *set inform1 6
        *set defiance +1
                
What did you do with your Juice vial, ahead of the mission?
*choice
    #I drank to stay on top form.
        *set vials 0
        *set juice 100
    #I drank, to avoid my powers turning on me.
        *set vials 0
        *set juice 100
        *set dependence +1
    #I drank to fight off the cravings.
        *set vials 0
        *set juice 100
        *set dependence +2
    #I didn't drink, in order to pace myself.
        *set vials 1
    #I didn't drink: I'm concerned about dependency.
        *set dependence -2
    #I smashed the vial.
        *set vials 0
        *set smashed true
        *set defiance +3
        *set dependence -5
        
*if (jumpahead = 5)
    You're all set!
    *page_break Proceed to Chapter 6.
    *goto_scene zone
    
*else
    *set routeout 5
    *set houndsmet true
    *set tag true
    *set juice -30
    *if juice < 0
        *set juice 0
    
    How smoothly did the infiltration go?
    *choice
        #Incredibly so, and we destroyed the footage.
            *set footagedestroy true
            *label gotstuffstuff
            *set shades true
            *set logs true
            *set photo true
            *set weirdblood true
        #We didn't get the footage, but it was pretty smooth.
            *set alarmlevel 1
            *set heat 2
            *goto gotstuffstuff
        #Could have gone worse.
            *set alarmlevel 2
            *set heat 3
            *set logs true
            *set photo true
            *set weirdblood true
        #It was a shambles.
            *set alarmlevel 3
            *set heat 4
            *set logs true
            *set photo true
            
    What happened with Not-Prii?
    *choice
        #I fended them off.
            *set scan false
        #I passed out.
            *set scan true
            *set facezone true
            
    Did Wil have to save you from Vantage?
    *choice
        #No, I handled her myself.
            *set voutcome 2
        #Yes.
            *set poutcome 4
            *set ghouldvibrations true
            *set voutcome 4
        
    Did you realise the identity of a certain Glory Hound?
    *choice
        #Yes.
            *set ephalanx true
        #No.
            *set ephalanx false
        #Yes, and I shouted to them.
            *set ephalanx true
            *set doubt_gh + 15

    Were you shot by Enfilade?
    *choice
        #Yes.
            *set getspiked 3
            *set mc_health 3
            *set injurydesc 9
        #No.
            *set getspiked 1
            
    How did things shake out with Surpass?
    *choice
        #Gonna be honest, I ran the hell away.
            *set soutcome 1
        *selectable_if ((speciality = 2) and (fighting_style = 3)) #I ran away, and got sort-of-decapitated in the process.
            *set soutcome 2
            *set remotemembrane 2
            *set mc_health 4
            *set injurydesc 9
        
        #We went toe-to-toe. And it did not end well.
            *set surpass_stomach 3
            *set mc_health 5
            *set injurydesc 9
            *set soutcome 5
        #I got hit by Juice withdrawals and collapsed.
            *set juice 0
            *set soutcome 8
            *set suppressants 2
            *set juiceless true
            *set nojuicezone true
            *set collapsezone true
            
    After it all went down, did you confide to anyone about your experience with Prii?
    *choice
        #Dion.
            *set confide 2
        #Mal.
            *set confide 3
        #Wil.
            *set confide 4
        #Kay.
            *set confide 5
        #Teddie.
            *set confide 6
        *selectable_if (inform1 < 5) #CG.
            *set confide 7
        *selectable_if (alinumber = 2) #Alistair. (though not the details, of course)
            *set confide 8
        #No.
            *set confide 1
        
    *if jumpahead = 7
        Of the Altruists, who do you feel closest to at present? (this artificially boosts the relationship to let you see a specific scene in Chapter 7. Note that if you've started a relationship with Wil, ${whis} scene takes precedence!)
        *choice
            #Dion.
                *set rel_architect 70
            #Mal.
                *set rel_wyrd 70
            #Wil.
                *set rel_wil 70
            #Kay.
                *set rel_kay 70
            #Teddie.
                *set rel_teddie 70
        
    *if (jumpahead = 6)
        Can… you [i]dance?[/i]
        *choice
            #Sort of?
                *set dance false
            #Can I dance? It was my childhood dream!
                *set dance true
            #Nope.
                *set dance false
        
        You're all set!
        *page_break Proceed to Chapter 7.
        *goto_scene masquerade
    
    *else
        *set rel_architect + 10
        *set rel_kay + 10
        *set rel_teddie + 10
        *set rel_wyrd + 10
        *set rel_wil + 10
        *set airystatus 2
        *set cgstatus 2
        *set businessmen true
        *if juice = 0
            *if (smashed)
                *set halpmecg 2
                
            *set juice 100
            
            *set dependence + 2
            *set juiceless false
            *set remotemembrane 1
            *set vantagebeating 1
            *if ((getspiked = 3) or (surpass_stomach > 1))
                *set injurydesc 9
                *set mc_health 2

            *else
                *set mc_health 1
                *set injurydesc 1

        Who did you spend time with at Masquerade?
        *choice
            #Mal.
                *set rel_wyrd %+ 15
            #Mal, and I went after them once they ditched me.
                *set rel_wyrd %+ 15
                
                *if subterfuge > 39
                    *set wyrdmeet 1
                    
                *else
                    *set doubt_wyrd +10
                    
            #Alistair.
                *set aliclub 3
                *set doubt_alistair + 5
                *set rel_alistair + 20
                
            #I danced with a stranger.
                *set metrico true
                *set dancepartner 4
            #Variable found me somehow.
                *set airytalk 3
            
        *if knowledge > 44
            *set doubt_architect +5
            *set doubt_wyrd +10
            What happened with the Businessmen's target?
            *choice
                #I hesitated a bit.
                    *set watson 2
                    *set grey +1
                #An easy takedown.
                    *set watson 2
                    *set business_respect +1
                #I messed him up.
                    *set watson 2
                    *set brutal +1
                #He wound up dead, accidentally.
                    *set brutal + 3
                    *set watson 3
                    *set accidentkill true
                    *set killer true
                    
                    *gosub moider
                #I killed the guy.
                    *set psycho + 2
                    *set brutal + 3
                    *set watson 3
                    *set killer true
                    
                    *gosub moider
                    
            *goto masqscenefinish
            
            
        *else
            What happened with that security guard?
            
            *choice
                #Took him down as gently as I could.
                    *set grey +1
                #I dealt with him.
                    *set business_respect +1
                #I messed him up.
                    *set brutal + 1
                #He wound up dead, accidentally.
                    *set brutal + 3
                    *set accidentkill true
                    *set killer true
                    *set rentcop true
                    
                    *gosub moider
                #I killed the guy.
                    *set psycho + 2
                    *set brutal + 3
                    *set killer true
                    *set rentcop true
                    
                    *gosub moider
            *goto oclf        
             

*label moider
And…
*choice
    #I don't regret it.
        *set psycho +1
        *set brutal +1
        *set rel_wyrd %- 15
        
        *return
    #I'm so, so guilty.
        *set guiltkill true
        *set rel_wyrd %- 10
        
        *return
    
*label oclf
*if (guiltkill)
    *set libra 4
    *set fissionmailed true
    
*else
    *comment 1 never encounter her 2 allow escape 3 allow escape (nice) 4 panicking over dead guy 5 convince to throw 6 fight and win 7 indirect fight/reinforcements 8 fight and lose 9 intel 10 zoooom
    How did the confrontation with Libra pan out?
    *choice
        #I let her get away: I had to prioritise the Coven.
            *set defiance - 1
            *set rel_cg %+ 10
            *set trust_cg - 1
            *set libra 2
            *set covenstr +1
            *set fissionmailed true
            *if doubt_hypothesis > 9
                *set doubt_hypothesis - 10

            *else
                *set doubt_hypothesis 0
        #I couldn't bring myself to hurt her.
            *if (interest_cg)
                *set flirt_cg +2
                            
            *set trust_cg +1
            *set rel_cg %+ 15
            *set libra 3
            *set fissionmailed true
            *set covenstr +1
            *if doubt_hypothesis > 9
                *set doubt_hypothesis - 10
                                
            *else
                *set doubt_hypothesis 0
            
        *selectable_if ((inform1 < 5) or ((inform1 >4) and (footagedestroy = true))) #I convinced her to throw the fight.
            *set libra 5
            *set covenstr - 1
        #I beat her in a fight.
            *set libra 6
            *set trust_cg +1
            *set business_respect +1
        #I beat her with some help from Mr. White.
            *set trust_cg +1
            *set libra 7
        #I fought her, but I lost.
            *set trust_cg +1
            *set libra 8
            *set fissionmailed true
        #I managed to swipe the intel she was after.
            *set libra 9
            *set trust_cg +1
        #She escaped before I could get her pinned down.
            *set libra 10
            *set trust_cg +1
            *set fissionmailed true

*label masqscenefinish
What happened in your dream, with those strange kids?
*choice
    #A figure demanded I leave, and I woke up.
        *set aqt 0
    #I followed, then left while I had the chance.
        *set amlvl +1
    #I hung back, and then woke up.
        *set amlvl 1
    #I don't remember.
        *set amlvl +2
        *set aqt +1
        *set dreamforget true

*if jumpahead = 7
    You're all set!
    *page_break Proceed to Chapter 8.
    *goto_scene atrois

*else
    *set rel_teddie + 10
    *set rel_architect + 10
    *set rel_wyrd + 10
    *set rel_kay + 10
    *set rel_wil + 10
    *if ((aliname) and (not (pseudonym)))
        *set aliventure true
    *if (libra = 1)
        *set trust_cg +2
        *set rel_cg %+ 10
    *set scum true
    *set doubt_alistair +5
    
    Did you eavesdrop on Dion and Mal?
    *choice
        #Yes.
            *set archqualms 1
            *set archinfo +1
            
            *if subterfuge < 25
                *set bustedmal true
                *set doubt_wyrd + 15
                *set doubt_architect + 15
                *goto acinv
                
            *else
                And did you stick around to hear as much as possible?
                
                *choice
                    #Yes.
                        *set archother 1
                        *set archinfo +1
                        
                        *if (subterfuge > 45)
                            *goto acinv
                        
                        *else
                            *set doubt_wyrd +20
                            *set doubt_architect + 20
                            *set bustedmal true
                            *goto acinv
                        
                            
                    #No, I dipped out.
                        *goto acinv
           
        #No: too risky.
            *goto acinv
           
    *label acinv
    *if ((aliclub = 3) or (alinumber = 2))
        Did you take Alistair up on his invitation to the café?
        *choice
            #Yes.
                *set alicafe 2
                *set rel_alistair +15
            #No.
                *set alicafe 3
                
    Were you running low on Juice at this point?
    *choice
        #Yes.
            *set juice 100
            *set nojuicemid true
            
            *if vials = 1
                *set vials 0
                *goto nfguice
                
            *else
                
            *set dependence + 2
            *set juiceless false
            *set remotemembrane 1
            *set vantagebeating 1
            *if ((getspiked = 3) or (surpass_stomach > 1))
                *set injurydesc 9
                *set mc_health 2
            *else
                *set mc_health 1
                *set injurydesc 1
                
            *if ((footagedestroy = false) and (inform1 > 4))
                *set halpmecg 3

            *else
                *set halpmecg 2
                
            *goto nfguice
        #I was doing okay.
            *set juice -10
            *goto nfguice
        
*label nfguice
Did CG confide in you about her plan?
*choice
    #Yes.
        *set cgtell true
    #No.
        *set cgtell false

    
*if (aro != 4)
        Do feelings seem to be developing between you and Alistair, CG, or both?
        *choice
            #Yes, Alistair.
                *set interest_alistair true
                *set flirt_alistair +3
            #Yes, CG.
                *set interest_cg true
                *set flirt_cg +3
            #Both.
                *set interest_alistair true
                *set flirt_alistair +3
                *set interest_cg true
                *set flirt_cg +3
            *selectable_if (aro = 1) #Both, and uh, I think they like each other too.
                *set interest_alistair true
                *set flirt_alistair +3
                *set interest_cg true
                *set flirt_cg +3
                *set polyflag_acg true
            #Neither.
                *set interest_alistair false
                *set interest_cg false
            
    
    
*if jumpahead = 8
    You're all set!
    *page_break
    *goto_scene hounds

*else
    *set met_phalanx 1
    *if rel_beth > 80
        *set rel_phalanx +40
    *else
        *set rel_phalanx +30
    
    Did you run interference for CG?
    *choice
        #Yes.
            *set helpoutcg 1
            *set trust_cg +1
            *set rel_cg %+ 10
        #Nope.
            *set helpoutcg 3
            *set trust_cg -1
            *set rel_cg %- 10
        #I tried and failed.
            *set helpoutcg 2
            *set rel_cg %+ 5
    
    *if (((battitude = 2) or (battitude = 5)) or (brutal > 2))
        Did you punch Beth?
        *choice
            #Yes.
                *set bethpunch 2
            #Yes, multiple times.
                *set bethpunch 3
            #To the point of breaking down
                *set bethpunch 5
            #No.
                *set bethpunch 1
                
        *goto bcstory
    
    *else
        *label bcstory
        What cover story did you give Beth?
        *choice
            #That I was held captive, letting her fill in the blanks.
                *set bethcover 1
            #Just enough of the truth to dissuade questions.
                *set bethcover 2
            *if (subterfuge < 35)
                #I fumbled by claiming that I'd been injured, drawing suspicion.
                    *set bethcover 3
                    *set doubt_gh + 10
            #I didn't tell her shit.
                *set bethcover 5
                *set doubt_gh + 5
                *set rel_phalanx -10
            *selectable_if (subterfuge > 50) #I lied my ass off.
                *set bethcover 4
            #I froze up entirely.
                *set bethcover 6
            
        How was your relationship with your parents?
        *choice
            #Distant.
                *set parents 1
            #Poor.
                *set parents 2
            #Terrible.
                *set parents 3
                
                
        Now that you know what's going on with Alistair, what's your opinion?
        *choice
            #He's as close to the DPR as makes no difference.
                *set alitude 1
            #I genuinely have no idea.
                *set alitude 2
            #I'm relieved he's only a tech guy; not a threat.
                *set alitude 3
            #I'm relieved he's only a tech guy; I was worried I'd have to hurt him. 
                *set alitude 4
            #Maybe I can take advantage of his position.
                *set alitude 5
            #I like having him around either way.
                *set alitude 6
                
        And…
        *choice
            #It's just a bad idea to associate with him.
                *set alicut true
                
            #I'll keep in contact.
                *set alicut false
                *set polyflag_acg false
            
    
*if jumpahead = 9
    You're all set!
    *page_break
    *goto_scene covenmeeting
    
*else
    *if (vials = 1)
        *set coveninfo +1
        *set heknew true
    Did you attack Catalyst?
    *choice
        #Yes.
            *set scrapcat true
            *set rel_catalyst +1
            *set defiance +1
        #No.
            *set scrapcat false
    
    *if ((inform1 > 4) and (not (footagedestroy)))
        You got caught out for withholding information. What happened next?
        
        *choice
            #I got the shit kicked out of me. @{(rel_cg > 65) CG tried to help at least.|}
                *if rel_cg > 65
                    *set intervene true

                *set punish 4
                *set defiance - 2
                *set doubt_hypothesis +10
            #I managed to talk my way out of punishment entirely.
                *set punish 2
            #I threw myself on Hypothesis's mercy, sacrificing all dignity.
                *set punish 3
                *set defiance -3
                *set doubt_hypothesis - 5
                *set trust_cg - 1
                *set rel_cg - 10
            #I talked my way out of the worst of the punishment.
                *set punish 5
                *set doubt_hypothesis +10
            
      
        *goto allabz
    *else
        What report did you make to Hypothesis?
        *if (inform1 < 5)
            *choice
                #I told him all about the Zone.
                    *label allabz
                    *set inform2 1
                    *set covenstr +2
                    *goto spendtimeprivate   
                #I was selective in what I told him.
                    *set inform2 2
                    *set covenstr +1
                    *goto spendtimeprivate   
                #I fed him direct misinformation.
                    *set inform2 3
                    *if (subterfuge > 39)
                        *set covenstr -1
                        
                    *else
                        *set doubt_hypothesis +10
                        
                    *goto spendtimeprivate   
                        
            
        *else
            *choice
                #I waffled about the Altruists.
                    *set inform2 5
                    *set doubt_hypothesis +5
                #I admitted/lied that I hadn't made any progress.
                    *set inform2 5
                    *set doubt_hypothesis +5
                #I told what I knew.
                    *set inform2 3
                    *set covenstr +1
                #I deflected the responsibility onto CG.
                    *set inform2 6
                    *set trust_cg - 1
                    *set rel_cg %- 10
                    
            *goto spendtimeprivate   
                    
                    
    *label spendtimeprivate
    Did you spend time talking with CG in private?
    *choice
        #I did.
            *temp talkingtocg 2
            *temp aboutwork 0
            *set talk_cg_hq true
            
            You spoke about…
            *label cgmenu
            *choice
                *disable_reuse #AdVenture.
                    *set aboutadventure_cg true
                *disable_reuse #My history with Beth.
                    *if (dated_beth)
                        Specifically:
                        *choice
                            #Including that we dated.
                                *set aboutbeth_cg 4
                            #I left that part out.
                                *set aboutbeth_cg 3
                                
                    *else
                        *set aboutbeth_cg 2
                        
                *disable_reuse #Advice for my mission.
                    *set aboutwork +1
                    *set cg_insight true
                *disable_reuse #The new Juice.
                    *set aboutwork +1
                *disable_reuse #The intel she was trying to get from the Businessmen.
                    *set aboutwork +1
                    *set covenbusinessintel true
                    *set coveninfo +1
                    *set rel_cg %- 10
                    *set instinctive %- 10
                *disable_reuse #We just talked.
                    *set rel_cg %+ 10
                    *set cgfood true
                    
            *set talkingtocg -1
            *if (talkingtocg > 0)
                Also…
                *goto cgmenu
            *else
                *if aboutwork = 0
                    *set trust_cg +2
                    *set connectcg true
    
                *elseif aboutwork = 1
                    *set trust_cg +1
                
            
            Did you exchange names with CG?
            *choice
             #Yes.
                *set rel_cg %+ 10
                *set trust_cg +1
                *set cgmc forename
                *label furtherthingscg
                *if (interest_cg)
                    And did things go further with her?
                    *if (romance_wil > 2)
                        *choice
                            #Yes, and what Wil and Mirella don't know won't hurt either of them. @{(brokenheart < 5) I still froze up though.|}
                                *if (brokenheart < 5)
                                    *set romance_cg 2
                                *else
                                    *set flirt_cg +2
                                    *set romance_cg 3
                                    
                                *goto jumpahead10
                            #Yes, and I told her about Wil. @{(brokenheart < 5) But I froze up partway through.|}
                                *set mention_wil_cg true
                                *if (brokenheart < 5)
                                    *set romance_cg 2
                                *else
                                    *set flirt_cg +2
                                    *set romance_cg 3
                                    
                                *goto jumpahead10
                            #I couldn't do that to Wil.
                                *set hesitate_cg 3
                                
                                *goto jumpahead10
                            #They did not.
                                *goto jumpahead10
                            
                    *else
                        *choice
                            #@{(brokenheart < 5) Yes, but I froze up.|Yes.}
                                *if (brokenheart < 5)
                                        *set romance_cg 2
                                *else
                                        *set flirt_cg +2
                                        *set romance_cg 3

                                *goto jumpahead10
                            #I didn't have the energy to think on it clearly.
                                *set hesitate_cg 2
                                *goto jumpahead10
                                
                               
                *else
                    *goto jumpahead10
             #No.
                *goto jumpahead10
             *selectable_if (pseudonym) #I explained I actually prefer my pseudonym.
                *set cgmc aka2
                *goto furtherthingscg
        #I did not.
            *set talk_cg_hq false
            *goto jumpahead10
            
            
*label jumpahead10            
*if jumpahead = 10
    You're all set!
    *page_break
    *goto_scene scum
    
*else
    Placeholder! Go to the mission anyway!
    *goto_scene scum

*label startingscene

The tendrils are restless.

You watch your pair of extra limbs wend their way through the air, twisting and writhing. They're ink dark, and you know that the smooth coating across your head, shoulders, and arms shares the same hue.

Once, the tough membrane covering your face might have bothered you. Now, it simply comes with the territory.

The tendrils continue their wriggling, and one of them brushes against the door frame of the maintenance room you currently crouch within.
*fake_choice
    #They're irritating me. I still them.
        It's a simple thought to quell the motions and the barest hint of concentration to maintain the stillness.
    #I can't reveal myself yet. I pull them back.
        A simple thought suffices to retreat the tendrils from the doorway.
    #I'm nervous and need an outlet. I let them be.
        Before long, the adventurous tendril retreats by itself. Their motions sooth the need to fidget; otherwise you'd most likely be bouncing a leg.

Despite their propensity to wander, the tendrils can't do anything more than gently squirm unless you will it. A very good thing, considering their capabilities.

You've waited in this room for five minutes already, lurking amongst lockers and tool shelves. Behind and above you, the hatch to the roof you entered by remains open.

The door stands ajar by a mere fraction, just enough to allow a thin sliver of light to creep past. More importantly, enough that you can hear the ongoing commotion downstairs.

There's a shout from below, followed by the sound of splintering wood.

You don't move.
*fake_choice
    #I'm content to bide my time for the opportune moment.
        *set instinctive -10
        You have no issues with waiting. Patience is a virtue.
    #It doesn't matter what I think.
        Like them or not, you have your orders.
    #I hate waiting around like this, but my hands are tied.
        *set instinctive +10
        If you had it your way, you'd be right in the thick of things already.

Seconds tick by into minutes as you remain motionless—save the odd drifting tendril—and the crashing and yelling beneath you develop into the din of a full blown fight.

*if instinctive > 51
    You slowly clench and unclench your fists, tendrils growing more agitated. Are you seriously still waiting around?
    
*elseif instinctive <49
    You let the noise wash over you. Clearly, if the fracas downstairs is in full swing, then you'll have your chance soon enough.
    
*else
    You wonder how intense it's going to get before you're able to make your move. These types of fights are often over quickly.

A voice crackles in your ear.

[i]"Go."[/i]
*fake_choice
    #"Understood."
        As expected, the voice says nothing further.
        
    #I don't speak, I move.
        There's nothing to say, and you'd receive no reply in any case.
        
    *selectable_if (instinctive > 49) #"Finally!"
        You don't expect a reply, and don't receive one either.
    *selectable_if (instinctive < 51) #Patience pays off.
        You nod calmly to yourself, though you say nothing. This isn't a conversation.

Rising to your feet, you part the membrane over your ear and extract the small bud from it. Stowing the device for safekeeping, you push open the door and stride out of the room.

*page_break Into the fray.

The noise of combat instantly redoubles, intensifying with each step as you approach the nearby balustrade. Beyond it, the room opens out into an atrium, and the floor below your vantage point is the battlefield.

A vibrant purple laser blasts from the hand of a lean man clad in black, red-accented spandex. The beam races across the lobby on unerring course for a person who, save the simple domino mask concealing their eyes and the baseball bat in their hand, is dressed more for a casual night out than a superpowered brawl.

Before the laser can wipe them out, a shimmering cuboid of energy rises from the tiled floor and intercedes, absorbing the attack soundlessly. Nearby, a figure wearing a featureless white helmet and a grey longcoat calmly lowers their arm.

"Ooh! Not bad!" the first man calls. "Enfi! You see that?"

"Focus, Arcade!" barks another voice from out of view.

You aren't here just to watch. You place a hand on the balustrade and prepare to vault.
*fake_choice
    #I have to clamber over. I'm very short.
        *set mc_height 2
        *set guts -2
        *set subterfuge +2
    #I'm short, so crossing over is a bit of a chore.
        *set mc_height 3
        *set guts -1
        *set subterfuge +1
    #It's neither too easy nor too hard. I'm average in height.
        *set mc_height 4
    #I'm tall enough that I can clear it easily.
        *set mc_height 5
        *set guts +1
        *set subterfuge -1
    #I can more or less step straight over. I'm very tall.
        *set mc_height 6
        *set guts +2
        *set subterfuge -2

You clear the balustrade, steel yourself, and leap.

*fake_choice
    #I'd prefer a more subtle entrance, but that isn't the brief.
        *set expressive -10
        Your tendrils are extended ahead of you before you even jump, and as you drop towards the ground, you simply reach out. They cushion your fall with only the slightest sensation of impact, and you almost-elegantly manoeuvre them to deposit you onto your feet. 
    #Screwing this up would be humiliating. I concentrate on sticking the landing.
        You whip out your tendrils as the ground rushes to meet you. As intended, they touch down first, cushioning the fall with only minor shocks reverberating back through them. Great, screw up successfully averted.
    #I want as much attention as possible.
        *set expressive +10
        *set wreckage true
        You coil your tendrils up as you drop. The instant before you slam into the ground, you piston them back out. Dual sharp cracks echo through the air, the force of the impact rattling back through your entire frame. The tiles below you are shattered, and there's a tight smile on your face. Entrance. Made.

*set arcade true
*set juice -5
The sudden presence of a third party brings the fight to a momentary standstill, all four combatants stopping to size you up. That's to your advantage, giving you a couple of seconds to assess the situation from ground level.

First, you locate the unseen voice; a large, pale-skinned woman with a shaven head and metal visibly woven into her arms stands to your left, not too far behind Arcade. The new augment in town, Enfilade.

Next, you take in your surroundings. @{wreckage Yours, you note, isn't the only rubble strewn about the place; t|T}he lobby is a real mess already, the remnants of a good deal of furniture scattered over the floor, broken glass everywhere underfoot, and beyond Enfilade, a conspicuous hole in the wall.

You've looked. Time to act.
*choice
    #I sucker punch Arcade.
        Not only is he closer to you, he doesn't even have his hands up to protect himself.
        
        "Uhhh. Hey… buddy?" Arcade calls to you as you take a subtle step in his direction.
        
        "Arcade! Does that look like a buddy to you?" Enfilade snaps.
        
        "I don't believe in judging books by their cover—" the word blends into a yelp as your tendril lashes out for his face. He reacts to dodge faster than you expected, and your blow glances off his shoulder. "Okay nevermind! Judging!" His hands begin glowing as he backpedals.
        *goto beginfight
    #I'll throw something at Enfilade, she won't expect it.
        There's quite a distance between you and her, which should allow you to catch her off guard.
        
        Enfilade breaks the silence. "Identify yourself, or you will be assumed hostile!" she snarls.
        
        "Aw, Enfi, c'mon!" Arcade turns to his teammate. "You don't have to be all serious business, I'm sure @{wreckage the property damage wasn't intentional.|they're friendly.} Right, newbie?" He looks back right as you hurl the large potted plant you were picking out straight at Enfilade's head.
        
        With a curse, she barely reacts, blocking your missile with her arm. The decorative succulent explodes in a shower of ceramic and dirt. 
        
        "Okay, uh, statement withdrawn!" Arcade is grinning sheepishly, but both hands begin to glow.
        *goto beginfight

*label beginfight

"Architect! You been recruiting behind my back?" shouts domino mask.

"Not now, Wyrd," longcoat answers mechanically.

You don't hear if the conversation continues, because you're busy diving to one side, evading two fresh lasers from Arcade.

Rolling back to your feet, you're immediately in motion. The pair of heroes don't work alone; the entire rest of the Glory Hounds are probably on their way already. By contrast, you doubt two villains are going to assist you with no questions asked.
*page_break Duck another laser.

Arcade's blasts aren't too powerful uncharged, but if you let him pin you down, Enfilade will take you out at her leisure. To deal with him quickly and decisively, you'll need to rely on your training.

You summon up the lessons that stuck closest to you, those which developed from interest to affinity to expertise.
*choice
    #Hand to hand combat.
        *set fighting_style 1
        [i]"You'd be surprised how many parahumans can't throw a punch worth shit."[/i]
        
        Thanks to hard-earned experience, you aren't amongst that category.
        
        Quickfire lasers continue to pursue you, but you remain mobile, moving with purpose to cut down Arcade's angle of fire. Dipping a shoulder, you evade another blast, and then push off from your trailing foot, launching forward.
        
        By the time Arcade reacts to your sudden charge, it's too late, you're already on top of him. You throw an overhand haymaker, connecting flush with his jaw and staggering him. He just barely blocks your follow up right hook, but the next two punches in the combination crush straight through his weak guard. 
        
        On wobbly legs, Arcade takes a desperate swing. You sway out of reach, and then retaliate with a fierce knee strike to the solar plexus, doubling him over.
        
        Arcade can't measure up to you in close quarters. Now's your chance to remove him from play for a little while.
        *fake_choice
            #Excellent. I'll take him down cleanly.
                No need to overdo it. Most underestimate how debilitating a winding blow can be.
                
                You target Arcade's abdomen with another precise knee. Any air remaining in his body rushes out of him and he collapses, wheezing.
                
                Good. He'll be recovering from that for a while.
            #I'm going for maximum damage.
                *achieve beatemup
                *set brutal +1
                *set arcade_nose true
                *set arcade_beef 2
                You grip the back of Arcade's head in both hands, then pull him down. In unison, you drive your knee upwards as hard as you possibly can.
                
                There's a hideous crunch and a spray of blood. Arcade crumples unceremoniously to the floor, face streaked with an altogether different mask. He's not getting up any time soon.

        There's a crash from nearby. Enfilade just sent Wyrd—the plain clothes villain—flying with a martial arts throw. Looks like they jumped in to help after all.
        
        Freed up, Enfilade studies you, sudden interest sparking in her eyes. "Muay Thai, huh?" She beckons to you, raising her fists in a fighting stance.
        *choice
            #I can wear her down, especially with backup.
                *set instinctive -2
                If Wyrd and/or Architect have decided you're on their side, or at least that the enemy of their enemy is a friend, then the numbers are in your favour and you just have to keep Enfilade occupied.
                
                You advance on her, testing the waters with a foot thrust, which she blocks, absorbing the pushing force and remaining steady. She counters with a jab-straight combination, and you sway back, deflecting her follow-up hook punch, though the impact on your arm sends tingles through your limb.
                
                Enfilade keeps on you aggressively, and you punish it with a whip of a leg kick that lands hard and makes her stumble.
                *goto brawlin
            #If she wants a brawl, she's getting one.
                *set instinctive +2
                You raise your own hands. Enfilade smiles, teeth bared.
                
                Swiftly crossing the distance, you test her with a front kick, which she handily parries. She counters with a jab-straight combination, you block. You aim an elbow to her head, but Enfilade catches it on her arm with a weighty clunk that sends a shock back through you. She attempts a punch, but you cut it off with a quick foot thrust to the torso, pushing her back and off balance.
                *label brawlin
                *fake_choice
                    #Press the attack. No openings.
                        You advance, leading a jab, then torquing your hips into a powerful roundhouse. You feel a satisfying impact as you connect with Enfilade's abdomen, and she staggers, leaving just enough space for you to follow through with an elbow strike. Enfilade gets rocked. You press on, unrelenting, and throw a vicious overhand—
                        
                    #Get flashy. Flying knee.
                        *set expressive +3
                        You advance, fake a punch, and then launch yourself into a flying knee which slams right into Enfilade's chin. She drops, and you rush in to exploit her vulnerability, only to take a hard upward kick from the ground. You stumble, allowing her the space to stand as you recover.
                        
                        "Cute move," she growls. You smirk, though she can't see, and quickstep forward, throwing a vicious overhand—
                        

                Enfilade catches your fist. Her grip is iron. Before you can wrench free, she grapples you around the torso, pops a hip, and brings you crashing to the floor with a brutal throw. You've barely got the wherewithal to jerk your head to the side as she drives a punch straight into the ground, inches from your ear.
                *fake_choice
                    #I'm good enough to fight my way out of this.
                        *set enfilade_fight true
                        Call it a point of pride, or perhaps holding on to a trump card, but you want to keep this purely hand to hand for now.
                        
                        On your back is a dangerous place to be in a brawl, and you move to correct that by ramming your heel into Enfilade's shin, almost driving her foot from underneath her. You roll to the side, shrugging off an attempted grapple, and rise back to your feet.
                        
                        Enfilade's done with the feeling out process, and immediately charges, putting you onto the defensive. Even while blocking her strikes, even with your power's protective membrane, the sheer force shockwaves through your body. You grimace, continue protecting yourself, and when you see an opening, launch out of the pocket to slam an elbow directly into her jaw.
                    #I bring my powers into play.
                        *set juice -5
                        You've kept your tendrils mostly out of the fight to this point, but they serve as an excellent boost to your combat capabilities.
                        
                        Before Enfilade can retract her fist, you lash out a tendril, clubbing her stooping form across the shoulders. You swipe the other tendril at her feet, and the combo nearly sweeps her onto the floor. Still, with your opponent reeling for balance, you have enough space to use both tendrils as a launchpad, bouncing yourself back to your feet.
                        
                        If your sudden switch of the rules of engagement bothers Enfilade, she doesn't show it. She charges, putting you right back onto the defensive. You're able to block her strikes with your arms and tendrils, but the sheer force still shockwaves through your body, even through your power's protective membrane. You grimace, continue protecting yourself, and then seize upon an opening to slip past her punch and 'elbow' her clean in the jaw with a tendril.
                        
                Enfilade staggers, but before you can exploit that any further, she reassumes her stance, shaking off the hit like it never landed in the first place.
                
                Right. She's an augment. Who knows what kinds cybernetic enhancements are loaded into her body?
                
                @{enfilade_fight "You can fight, but you can't win.|A couple tricks aren't enough.} Give it up."
                *goto wyrdentry_e
    #Adaptability and thinking on my feet.
        *set fighting_style 2
        [i]"You're not a meathead, so quit acting like one. Use your brain, yeah?"[/i]
        
        Brute force can't always get the job done, and that's something you've taken to heart. When the error margins are razor thin, remaining flexible is a key strength.
        
        Arcade is attempting to corral you. Knowing your opponent's intentions is a major advantage, and as you dodge around the lasers, you focus your mind on turning the tide in your favour.
        
        You feint in one direction, and then dart in the other, using a tendril to boost yourself. Arcade's next blast is wild, and you can tell he's struggling to adjust. Enfilade scowls in the corner of your eye, unable to get a clean shot at you. Their teamwork is lacking, and you have an opportunity.
        *choice
            #Perhaps I can dupe Arcade into hitting his ally.
                Use the resources you have, especially if that involves robbing the opposition of theirs.
                
                You juke once again, increasingly diverting Arcade's lasers from their mark. He's growing frustrated, attempting to predict your movements and missing wildly.
                
                Excellent. You read intent in Arcade's face and spring into action, swinging around to his opposite side. Arcade wheels and fires in the same moment.
                
                The laser streaks straight at Enfilade, and her split second dodge isn't quite enough to avoid getting clipped. She crashes inelegantly to the ground.
                
                "Shit! Sorry!" Arcade yelps.
                *fake_choice
                    #Now's my chance. Take him down while he's distracted.
                        *set instinctive +2
                        Your strafing has created some distance between you and Arcade, so you have to rush him. Unfortunately, your movement catches his attention and he reacts, swivelling to face you and snapshotting two lasers. You're forced to dive to the ground, the blasts zipping narrowly overhead.
                        
                        Hm. He's sharper than you thought.
                        
                    #If I keep him frustrated, he'll be a liability.
                        *set instinctive -2
                        "Terrific shot. Really."
                        
                        To your surprise, Arcade laughs ruefully. "Yeah I'm getting an earful later. That was sneaky."
                        
                        Hm. Arcade's calmer than he looks. Seems like you miscalculated.
                        
                        "Not sure who you are, honestly," Arcade continues. "Can I ask something?"
                        
                        You scrutinise him. He's clearly up to something; what could he be —
                        
                        You spot the glow of his hand just in time and hurl yourself to the ground. Arcade's hip height snapshot sizzles narrowly overhead.
                        
                        "Two can play at that game!" Arcade calls.
                        
                By the time you're back on your feet, Arcade has already started charging up again. Still, for the moment Enfilade is out of the picture, and you have the chance to deal with Arcade directly.
                *goto arcadeshoot
            #I'll manipulate his aim to endanger bystanders.
                *set brutal +1
                *set arcade_civvy true
                *set arcade_beef 2
                It's not honourable, but there are no points for good behaviour in a fight.
                
                The lobby has mostly cleared out at this stage, so it takes you a moment to locate a suitable target. However, you soon pick out a pair of civilians cowering behind a long desk.
                
                Perfect. You continue your unpredictable movements, increasingly diverting Arcade's lasers from their mark. Then, as you read the frustration in his face peaking, you swing to his opposite side. Arcade wheels and fires in the same moment, and there's a scream.
                
                The laser cleaves the desk in half and scores along the arm of one of the civilians. He goes down, yelling in pain.
                
                "Arcade! Watch your goddamn fire!" Enfilade shouts furiously, then rushes over to assist the injured man.
                
                Arcade looks utterly stricken. He stares at you.
                
                "That was messed up."
                *fake_choice
                    #"You were careless."
                        Arcade jerks back, stung. "If it wasn't for you, I wouldn't—" He takes a breath, composing himself.
                    #"Aw, upset you hurt someone?"
                        *set expressive +2
                        Anger hardens his face. "You're going down."
                    #I don't care what he thinks. I don't reply.
                        *set expressive -2
                        He sets his jaw. "Fine then."
                        
                The hero's hands glow, and you bounce on the balls of your feet. Enfilade is occupied, so you only have Arcade to worry about for the time being. Your actions netted the exact advantage you were seeking.
                
                *label arcadeshoot
                *choice
                    #Enfilade's still a factor. I have to deal with Arcade immediately.
                        *set instinctive +2
                        This window of opportunity is narrow, and you won't be able to open it twice. Pass through now or never.
                        
                        Once more you charge. Arcade raises his hands, and rather than shaping to dodge, you continue running full throttle. Two colourful lasers rocket towards you, and down come your tendrils to shield you from the blasts. Your prehensile limbs burn with pain as they take both hits, and you grit your teeth, maintaining course.
                        
                        You slam headlong into Arcade, bodychecking him straight off of his feet. He hits the ground hard, but as you make to follow up, he twists, cocks back his arm, and gets off a shot. Your tendrils are still shaking off the damage, too sluggish to intercept.
                        *choice
                            #Tank the hit and take him out.
                                *set mc_health 3
                                *set injurydesc 2
                                *set juice -5
                                You brace yourself and keep going. Your membrane should be up to this. Should.
                                
                                The laser takes you full in the chest. For an instant, your skin [i]sizzles[/i], and fiery agony radiates out from the impact.
                                
                                But you gut through it, and the initial sunburst fades into prickling needles. Arcade doesn't have time to charge up anything else before you're stomping him to the floor. Pinning him down with a knee to the shoulder, you rain punches into his face. One. Two. Three. Four.
                                
                                You pause midway through pulling your fist for punch number five. Arcade's out cold.
                                *fake_choice
                                    #Get up and assess the situation.
                                        Lowering your fist, you spring up to your feet. You just traded a nasty injury for removing Arcade from play, you can't afford to be careless.
                                        
                                        It's just as well you're paying attention, because you hear a hollow [i]thunk[/i] and duck, narrowly evading perforation by a hurtling metal spike. 
                                    #Hit him again. One for the road.
                                        *set brutal +1
                                        *achieve beatemup
                                        *set arcade_nose true
                                        *set arcade_beef 2
                                        *set pierced true
                                        *set injurydesc 3
                                        Ah what the heck.
                                        
                                        You go ahead and deliver the final punch. His nose crunches under your knuckles, spurting blood. He hurt you too, it's only fair.
                                        
                                        You're starting to rise when there's a hollow [i]thunk[/i]. Before you know it, something pierces the meat of one of your tendrils, and you bite back a curse.
                                        
                                You whip to face the direction of the shot. Enfilade is @{arcade_civvy finished up with medical treatment|back on her feet}. The synthskin of her arm has peeled back, exposing a launcher embedded beneath. She stares you down, @{pierced a grimly satisfied expression on her face|brow knotted in consternation}.
                                
                                @{arcade_civvy "You're a real piece of work, huh?|"Guess you didn't think you could take me yourself.} Back off of him@{pierced , before I put another in you.|.}"
                                
                                *goto archentry_e
                                    
                            #Dodge. It's not worth getting hurt.
                                Desperate as Arcade's floored laser may be, the angle is dangerous. You're forced to stop dead, snapping your head back as fast as you can. The blast sizzles past, close enough to feel the heat on your skin.
                                
                                You [i]think[/i] that your power's coating would hold up against one of Arcade's lasers, but you're far from eager to test that theory. Especially not with your face.
                                
                                Regaining your balance from such a dramatic motion takes a moment, and by the time you've planted your feet once more, Arcade has managed to stand up. In the process, he's also put some distance between you both. Back at square one, and he's staring you down calmly, flexing his hands. Waiting.
                                
                                *goto arcadedeal
                    #I'd rather play it safe and wait for a good opportunity.
                        *set instinctive -2
                        @{arcade_civvy Arcade managed to calm down after hurting a bystander,|Arcade kept his cool after hitting his own teammate,} you can't underestimate him.
                        
                        Instead of going back on the offensive, you give Arcade a once over, searching for any tells. His eyes are guarded and watchful, and you realise that just as you're measuring Arcade for another opening, he's studying you in kind, holding back from any more lasers and assessing your next move. It's a standoff.
                        
                        @{arcade_civvy He silently stares you down, though you catch his gaze briefly flickering over your shoulder. Worried about the man he clipped?|After a couple of seconds, he breaks the silence. "This feels a little wild west. Where's the tumbleweed?"}
                        *label arcadedeal
                        
                        Time, you remind yourself, is not in your favour. The onus is on you to act.
                        
                        *fake_choice
                            #I'll pretend he's being flanked.
                                You maintain a readied stance, and then ever-so-slightly turn your head, 'looking' beyond him. You recentre your gaze on Arcade, wait for a second, and then repeat the process.
                                
                                He frowns. "What are you—" Realisation hits, and he twists around to check his back.
                                
                                There you go.
                                
                                Springing to life, you rush him. This time Arcade's too slow on the draw, wasting his charged laser with a shot well wide of the mark. You hit him at full force, landing three punches in succession, and then slamming him bodily to the ground with your tendrils.
                                
                                You deliver a hard kick to his head, making damn sure he'll take his time getting back up.
                                
                                One down.
              
                            #I'll fake a retreat.
                                "Hm. This has been fun, but I have what I came for. Bye."
                                
                                You turn away and begin walking. Ahead of you, Enfilade @{arcade_civvy gives some final assurances to the injured civilian, ushering he and his companion out of the lobby.|catches Wyrd—the plain clothes villain—by the arm and sends them flying with a martial arts throw, seemingly recovered from the friendly fire.} Your window is almost shut.
                                
                                "@{arcade_civvy Where the hell do you think you're going!?|Whoa whoa! Hold your horses! You can't seriously think I'm just going to let you walk out!}"
                                
                                Pausing, you toss a glance back over your shoulder, like Arcade's an afterthought. @{arcade_civvy "I'm leaving, of course."|"Nothing I've seen suggests you can stop me."}
                                
                                Arcade scowls. You return your eyes forward and continue to walk away. Tension ripples through your body. Wait… Wait…
                                
                                The instant you hear the laser go off, you spring to the side. Planting a tendril, you push off from it and spin yourself around, immediately rushing Arcade. He's unprepared for the speed of your reaction, and doesn't even get off another blast before you're on top of him. You tackle him to the ground, simultaneously punching him in the throat with a tendril.
                                
                                He's left gasping on the floor, and you guarantee he's down for the count with a hard kick to the head.
                                
                                No time to lose. Enfilade probably has you in her sights already.
                                
                                
                                
                        *page_break A hollow [i]thunk[/i].
                        You react on instinct and duck, narrowly evading perforation by a hurtling metal spike.
                        
                        Whipping around to face the direction of the shot, you see Enfilade is indeed back into the fray. The synthskin of her arm has peeled back, exposing a launcher embedded beneath. She stares you down, brow knotted in consternation.
                        
                        @{arcade_civvy "You're a real piece of work, huh?|"Guess you didn't think you could take me yourself.} Back off of him."
                        
                        *goto archentry_e
          
    #Wielding my powers.
        *set fighting_style 3
        *set juice -5
        [i]"Not gonna be much of a parahuman if you suck with your powers, are you?"[/i]
        
        Mastery over one's abilities is usually far more critical than the exact nature of those abilities. Very strong powers become mediocre in the hands of an incompetent user. 
        
        You've developed an excellent understanding of your strengths and limitations, and you don't even have to think about it as you flit around the room, balancing, bracing, and boosting with your tendrils to move swiftly and remain several steps ahead of Arcade's lasers. You move unpredictably, racing in one direction only to instantly change course with a simple flick of the extra appendages.
        
        "Would you stop moving for like, three seconds?" Arcade shouts after a particularly wild blast. "I didn't have 'target practice with weird spider person' on my bingo card today!" He's hurrying after you as best he can, but struggling to make up any distance.
        *fake_choice
            #He can't keep up. I'll take the chance to rush him.
                You're dictating the pace, and that creates opportunities.
                
                The next time you change direction, you do so at an angle, cutting down the distance between you and Arcade without it being readily apparent. You start rushing in that new direction, but after just a couple of steps slam your tendrils hard into the floor and send yourself barrelling towards Arcade.
                
                Completely caught by surprise, Arcade reacts too slowly to defend himself. In a trice, you're on top of him, tendrils smacking into his face and chest so hard he goes momentarily airborne, and then crashes to the ground.
                
            #Spider, huh? I guess I'll show off.
                *set expressive +3
                Using both tendrils you push off the floor, launching yourself high into the air. So high, in fact, that you reach the level of the balustrade you first leapt from. You promptly latch onto it, using your tendrils to start crawling upside down along the lower level's ceiling.
                
                "I was kidding! Why are you so creepy!?" Arcade continues running after you, gaining now that you're not bounding around. Closer. Closer.
                
                There.
                
                You brace on the ceiling, twist, and then divebomb down onto him. Arcade gets off one final laser, streaking past your shoulder, and then you slam him into the ground with authority, bouncing his head off the tiles.
                
                
        Arcade's not moving, and you spare yourself a satisfied nod just as a wrecking ball of a fist crashes into your face, nearly knocking you from your feet.
        
        Enfilade is here.
        *fake_choice
            #Don't think, just react!
                *set instinctive +3
                Instantly, you bring your tendrils into play. The left shudders with the impact of Enfilade's next punch, the right lashes out, whipping across her eyes and letting you back up a step. Still operating on instinct, you kick out at Enfilade, driving her just a little further away and winning some breathing space to shake off the hit.
            #Defensive action. I need to get my bearings.
                *set instinctive -3
                Planting your tendrils, you push off, propelling yourself backwards at pace. Enfilade's next punch whistles past, missing by inches. You halt your momentum with the tendrils, rebalancing and trying to shake off the hit.
                
        Your ears are still ringing from the sheer force of that first blow. If it wasn't for your power's protective membrane, she might have knocked you out cold. She must have been closing you down the entire time you were giving Arcade the run around, and then charged you as soon as she saw a chance.
        
        Enfilade's already advancing. You need a game plan. Fast.
        *choice
            #Barb my tendrils to inflict more damage.
                *set juice -5
                You concentrate hard, feeling your tendrils shiver as their forms shift, studding with spikes. Elegant? No. Effective? Most definitely.
                
                Right as you finish, Enfilade closes the gap, swinging for the fences. You pull both tendrils in front of you in a sturdy block. Enfilade's strike connects, and while the impact sends shockwaves through your tendrils, she recoils, blood streaking down her knuckles.
                
                "What the—" Widened eyes flick between you and her wounded hand, and then her expression calms. "Ah. Interesting."
                
                It's a little galling to see her brush off one of your better techniques so calmly.
                *choice
                    #Still, she won't last long when she can't hit me without harming herself.
                        Provided you keep this fight up close and personal, you have the advantage.
                        
                        Enfilade seems to come to the same conclusion, beginning to back up, but you spring forward and refuse to allow her to open up any distance. You're much more manoeuvrable than she, enabling you to dictate the range of the engagement. To her credit, Enfilade swiftly realises that you aren't going to let her get clear, and begins focusing on fighting you.
                        
                        Just as expected, the barbs make it nigh impossible for her to find the right opening. With each strike she throws, you concentrate on using your tendrils for defense, and each hit that lands, she's scouring herself bloody. Enfilade switches tack, going for a grapple, but you wrap the tendrils around her back and squeeze, digging the spikes into her flesh.
                        
                        She attempts to throw you and you cling on, constricting her chest harder and harder. Sure enough after several seconds of sustained, rib-creaking pressure, she collapses.
                        
                        Your tendrils are warm with blood.
                        *goto wyrdentry_a
                    #She's pissing me off. I stab her somewhere non-fatal.
                        *set expressive +3
                        *set brutal +1
                        *set enfilade_injury 1
                        Lunging at her, you pull back your fist as if to punch her. Enfilade reacts immediately, snapping out her good hand to snatch your fist in mid-air.
                        
                        You grin a grin she can't see, and plunge a knife-tipped tendril into her abdomen. You look her straight in the eye as the pain and shock of what you just did lands, and then rip the bladed tendril free. 
                        
                        She's an augment. She can handle it.
                        
                        Enfilade drops to her knees, clutching at the wound, and then falls to one side.
                        
                        You feel blood running down your tendril.
                        *goto wyrdentry_a
            #Catch her off guard with an extra tendril.
                *set juice -5
                You've always had the sense that growing more than two tendrils is possible, but it's only recently that you've mastered the knack of doing so consistently.
                
                Now feels like a good time to pull out that trick.
                
                Concentrating hard, you push at your power, and are rewarded with fresh sensations as the third tendril starts to extend from your back. Carefully, you shield its growth from view with your body, and then as she closes in, you strike.
                
                The new tendril pistons over your shoulder like the sting of a scorpion, ramming Enfilade directly in the forehead. She stumbles, stunned, and you have a golden opportunity.
                *choice
                    #I pummel her with all three tendrils.
                        *label pummel
                        You launch a relentless assault, raining blow after blow on Enfilade. She's able to block the occasional hit, but it's not nearly enough, and you swiftly overwhelm her. Enfilade collapses to the floor under your flurrying tendrils.
                        
                        Everyone's stamina has limits. Even augments.
                        *goto wyrdentry_a
                    #I choke her out.
                        The heroes are likely to take a dim view of you strangling one of their own.
                        *choice
                            #On second thoughts, I'll just beat her down.
                                *goto pummel
                            #...And I care why?
                                *set brutal +1
                                *set enfilade_injury 2
                                So long as Enfilade's out of commission, you don't give a damn what it takes.
                                
                                You seize on her vulnerability and wrap a tendril around her neck, constricting hard. That breaks Enfilade's daze pretty damn quickly, and she immediately attempts to prise your grip loose.
                                
                                Not happening. You wield the other two tendrils to control her hands, though that's easier said than done as she wrenches ferociously from side to side, pulling you along bodily in a macabre dance. All the while, you keep up the pressure, clamping down on her airway.
                                
                                Soon enough, Enfilade is out of air and out of fight, and you choke her down to the floor, unconscious.
                                *goto wyrdentry_a
                    

*label wyrdentry_a
*page_break A laser streaks by.
*set ae 1
You instinctively step back, and then your head snaps in the direction of the blast.

"@{enfilade_injury Get the hell away from her!|Get the hell away from her!|Step right the heck back, buddy!}"

Arcade's looking worse for wear, but he's certainly back on his feet, a @{enfilade_injury furious|sickened|determined} expression on his face. He didn't miss, you realise, he was intentionally separating you from his teammate.

"I'm taking you down, right here and now."

Both of his hands are glowing intensely, and you tense up in anticipation of dodging.
*goto wyrdentry_e

*label wyrdentry_e

*page_break Wood splinters.
*set wyrdbat false

@{ae Arcade|Enfilade} drops like a stone. Revealed behind @{ae him|her} is @{ae the plain clothes combatant—Wyrd—|Wyrd, }grinning from ear to ear and holding half a shattered baseball bat. They flip what's left of their weapon in the air, catching it easily, and then wave their hand at the downed hero, like a magician presenting their trick. You have a moment to consider them in a little more detail; they're dark eyed and darker haired, wearing it short and floppy, and their skin is a pale tan brown.
*choice
    #"Thanks."
        "What are friends for?" Their smile takes on a sly curve.
        *fake_choice
            #"Friends, huh?"
                They wink. "Friends to be?"
            #"I don't know you."
                "Not yet, but I'd say we're on our way!"
        *goto wyrdentry_e2
    #"I had it handled."
        They tilt their head to the side. "I bet."
        *goto wyrdentry_e2
    #"Home run!"
        *set expressive +3
        *set rel_wyrd +1
        Wyrd gives you a little bow. "I'd call it an RBI triple, personally, but thank you, thank you."
        *fake_choice
            #I chuckle.
            #I nod, pretending I actually understand what that means.
        They favour you with a wink.
        *goto wyrdentry_e2
    #Nod acknowledgement.
        *set expressive -3
        If they're disappointed by your minimal reaction it doesn't show on their face, and they return the nod readily enough.
        *goto wyrdentry_e2

*label wyrdentry_e2

Wyrd jogs over, still smiling. "Nice to meetcha. Name's Wyrd, in case you didn't catch it—"
*goto convene_e

*label archentry_e

*page_break The launcher arms with a click.

The distance between you and Enfilade is significant. You certainly won't reach her before she lines up another shot, and she strikes you as more patient than Arcade. She'll pick her moment carefully—[i]thunk[/i]

You tense to dodge, but it turns out to be unnecessary. A translucent sphere rises in front of you and intercepts the spike, halting it dead in mid-air. Both spike and shape shudder.

Enfilade curses, then is promptly smashed from her feet as a cuboid of energy rockets from the wall behind her and rams into the back of her head.

The longcoated, helmeted figure from earlier—Architect—nonchalantly rises from behind an overturned table. He's holding a leather briefcase in one hand, and slowly lowers the other.

He inclines his head in your direction. One covered face regarding another.
*fake_choice
    #"Thanks."
        "Indeed."
    #"I could have handled that."
        "Perhaps."
    #"Were you hiding?"
        "No. Although striking from concealment was beneficial."
    #Nod acknowledgement.
        *set expressive -3
        *set rel_architect +1
        He returns the nod impassively.

*goto convene_a

*label convene_a
With that brief exchange, Architect turns his attention elsewhere, scanning the room. After a moment, he calls out. "Wyrd. Get up. We're leaving."

Groaning, his plain clothes companion—Wyrd—picks themself up from between two halves of a desk. "You're all heart, man."

In spite of his featureless helm, Architect somehow endeavours to look even more indifferent, and then begins striding towards the nearest exit. "I recommend you join us!" he calls, not looking back. "The Glory Hounds aren't known for taking it easy on new villains!"

Wyrd sighs and brushes off their jeans. You have a moment to take in a little more detail; they're dark eyed and darker haired, wearing it short and floppy, and their skin is a pale tan brown. One of those dark eyes promptly flashes you a wink. "I guess we're skipping introductions!" Wyrd takes off after Architect.

Naturally, you keep to yourself that you already knew both of their names long before today. You simply begin following after them.

*goto surpasstime

*label convene_e

"Introductions can wait, Wyrd," a voice interrupts from nearby. You turn to see their longcoated companion—Architect—approaching, a leather briefcase in one hand. "We can't afford delays."

Naturally, you keep to yourself that you already knew both of their names long before today.

"Okay, dad, sheesh." Wyrd shoots you a conspiratorial 'get a load of this guy' look.

Architect manages the impressive feat of conveying an eyeroll without visible eyes, and begins striding towards the nearest exit. "I recommend you join us!" he calls, not looking back. "The Glory Hounds aren't known for taking it easy on new villains!"

Wyrd pauses long enough to check that you're coming along, and then breaks into a trot once you start moving.

*label surpasstime
There was never a question whether or not you'd accompany the pair. After all, that's…

*page_break Exactly what you were ordered to do.
*set met_wa true
You push those thoughts away for the time being and concentrate on your surroundings. The first step is making a clean getaway, and success will depend on Architect and Wyrd's exit strategy; you're operating off very little intel.

There would be a certain irony if they were terrible at actually executing their heists, but you'd very much prefer if all your effort here didn't go to waste.

*if instinctive > 55
    In any case, you usually prefer winging it than planning everything out meticulously, so coming along for the ride without much foreknowledge isn't the worst thing in the world.
*elseif instinctive < 45
    Especially since you have a preference for preparation. Entrusting everything to a plan you know next to nothing about is making you uneasy.    
*else
    Still, that's the situation you're in at the moment. No point worrying over it.

Ahead of you, Architect makes for a small door labelled staff entrance on the left side of the lobby.
*fake_choice
    #I wonder if that was their entry point.
        Your limited information didn't extend further than the pair being sighted. The rest is a mystery.
    #I focus on the heroes. I don't want to get blindsided.
        Fortunately, a brief assessment of their conditions makes it clear that Arcade and Enfilade aren't about to leap back into the action.
    #I joke around with Wyrd to take my mind off things.
        *set expressive +2
        *set jokinground true
        "Hey, Wyrd!" They glance back at you. "What do you call an augment that got left out in the rain—"

Suddenly the front door explodes from its hinges. In its place stands a towering woman with medium brown skin, rippling with muscles. A shemagh conceals the lower half of her face.

@{jokinground "Not that," you conclude.|Uh oh.}

"Hey!" The woman swaggers into the lobby, spreading her arms wide. "Who's throwing a party without inviting me?"

You recognise her, and your stomach instantly drops.

Surpass. The Glory Hounds' biggest weapon. Strength, speed, and endurance wrapped in a single brazen package.

"Hold her off!" shouts Architect.

"On it!" To your astonishment, Wyrd fearlessly rushes at Surpass. She shrugs, sets her feet, and then meets them with a casual right hand.

Their head snaps to the side like it was a haymaker from a heavyweight boxer, but they follow their attack through regardless, @{wyrdbat slamming their bat straight into Surpass's chest, actually rocking her for a moment|letting fly with a punch of their own that's more enthusiasm than technique, landing solidly on Surpass's jaw}. 
*set surpasshere true
*fake_choice
    #I jump into the fight. Wyrd needs help!
        *set rel_wyrd +1
        *set instinctive +2
        You start racing over as fast as you can.
        
        It's not quick enough.
        
    #I join the fight. I need to make a good impression.
        *set rel_architect +1
        "Going!" you call to Architect, breaking into a run.
        
        It's not quick enough.
        
    #Surpass can't be taken lightly. I'll wait for a good opening.
        *set instinctive -2
        You advance slowly, studying them both. Wyrd did manage a hit, so she's not indestructible. There must be some way you can take advantage.
        
    #I'm more interested in what Architect's doing.
        *set instinctive -2
        He probably wouldn't throw Wyrd to the wolves just to make a getaway, so what's his game?
        
        Changing direction, Architect conjures a trio of energy blocks from the floor, angling them across Arcade's prone form. Your eyebrows rise, but then your attention gets pulled back to the others.
               

A laugh rings out. Surpass's eyes are alive with delight. "Oh man, I love it when they can take a hit."

Her fist flies, crashing into Wyrd's chest like a freight train. Their entire body ripples, the blow launching them through the air, soaring halfway across the lobby. Wyrd hits the ground on their back, flips over from the momentum, and then skids another couple of metres on their face before finally coming to a halt.

"Next!" Surpass crows, and then her gaze alights on you. "@{mc_height DUMMY|Huh. Hope you're just short and not an angry middle schooler.|Alright short, dark, and tentacled, you're up!|Yeah. You'll do. Bring it on!|Alright tall, dark, and tentacled, you're up!|Whoa. Is someone missing their massive-ass halloween skeleton? Think I can see your ribs.}"

No avoiding it now. You've got a one on one showdown with the strongest hero in the city.

If you hold back, Surpass will pulverise you. Forget relying on your regular techniques; there's only one tool in your arsenal that might be enough.
*choice
    #Creating 'nodes'; chunks of biomass able to act separately from me.
        *set speciality 1
        *set juice -40
        *set snick "Creepy"
        You don't think this will ever feel anything but viscerally [i]wrong[/i].
        
        Facing down Surpass, you focus inward, flexing internal muscles that never existed before your powers.
        
        The reaction is immediate.
        
        Your stomach roils and you double over, choking and gagging. Deep red ichor leaks from your mouth, passes through the membrane, and rains onto the ground. You shudder and contort, feeling a lump rising in your gorge, your throat bulging.
        
        You vomit explosively. Once, twice, thrice. Each heaving convulsion brings up a writhing cluster of black [i]mass[/i] to splat wetly in front of you. Instantly, you can feel your connection, the pervasive strangeness that is having parts of yourself separated from your body.
        
        "Dude, what the actual fuck!?"
        
        Slowly, you straighten, gulping huge breaths. Opposite, Surpass looks genuinely appalled. You can't see her mouth, but you suspect it's hanging open.
        
        The nodes crowd at the edges of your mind as they squirm on rudimentary dendrite limbs. They don't think, exactly, but they certainly possess instincts of their own. Gnawing hunger festers in your gut. The need to hunt. Feed.
        *choice
            #Directly engage Surpass, and then swarm with the nodes.
                You take advantage of Surpass's disgust and go on the offensive. However, she's not so shocked as to completely let her guard down, and she parries your swing with relative ease.
                
                The nodes want to be involved, want to be satiated. They're very different from the tendrils, and can't simply be moved like any other limb. A significant portion of your attention is consumed with the efforts of commanding them to hold back.
                
                *if mc_health > 1
                    Your body trembles with the effort of movement. Between your wounds and the exertion of creating the nodes, your stamina is reaching its limits. The next punch you throw is so tired and unsteady that Surpass simply leans out of the way. You overextend, and then Surpass thunders a strike of her own into your gut, sending another spray of ichor from your mouth. You attempt to inhale, but no breath comes as you collapse to your knees.
                    
                    Maybe this wasn't such a good idea.
                    
                    Surpass looms over you. "Okay, Creepy. Time to take a nap." She pulls back a fist. There's a surge of predatory instinct in your system, and a node pounces onto her arm, clinging and biting. "Agh! Get the hell off!" You feel the excitement and bloodlust of scenting prey, and the other nodes leap onto her in turn.
                    
                    [i]bite. tear. eat.[/i]
                    *label surpassnodes
                    *choice
                        #This might be my only chance to take her out. Attack!
                            *if mc_health >1
                                *set surpass_fight 3
                                *set mc_health 4
                                You muster every last ounce of strength and force yourself to your feet. The nodes are tenacious and slippery and Surpass can't quite get a hold of them to rip them clear, and all the while they continue biting and chewing.
                                
                                [i]eat. feed. eat[/i]
                                
                                Until, abruptly, their rows of teeth fail to penetrate Surpass's skin any longer. You feel the nodes' mouths [i]crunch[/i] against flesh so unyielding the very act of biting hurts them.
                                
                                [i]pain. prey. pain.[/i]
                                
                                Overwhelmed by the sensations, you stumble in your last-ditch rush. Surpass steps unhurriedly clear of your desperate swing, and then absolutely creams you with a headbutt straight to the face. You drop. Hard.
                                
                                *label nodesquish
                                Through the swirling stars of your vision, you have a dim awareness of Surpass prising one of the nodes loose and holding it aloft, wrinkling her nose.
                                
                                "Hey, creepy! Say 'what' if I can squish this thing without killing you or whatever."
                                *fake_choice
                                    #"...wha?"
                                        "Nice."
                                    #Groan.
                                        "Eh, close enough."
                                    #Don't say a damn word.
                                        "You're no fun. Eh. Science time."
                                    
                                *set nodedesc 2
                                *set nodecrushed true
                                Surpass crushes the node in her fist, and you arch your back in pain, convulsing as the feedback of its demise crashes into your system.
                                
                                [i]pain. gone. pain. pain. gone. flee.[/i]
                            
                                She does at least look abashed. That's wonderful recompense for the screams in your head. The other nodes leap clear of her, rushing back to cling to your legs fearfully.
                                *goto architectploy
                            *elseif fighting_style =1
                                *set surpass_fight 2
                                Righting yourself and setting your feet, you take a moment to marshal the tremors running through your body, forcing concentration and focus.
                                
                                [i]eat. feed. eat.[/i]
                                
                                Surpass can't quite get a grip on any of the nodes, slippery and tenacious as they chew at her flesh. It's an opening.
                                
                                Advancing into range, you lead with a thrusting knee strike, slamming it square into Surpass's abdomen. The nodes' excitement reverberates back through you, a rush of feral glee that etches an involuntary smile across your face.
                                
                                [i]hurt. bite. prey.[/i]
                                
                                Energised, you spin into an elbow, smashing Surpass in the jaw. She reels, the nodes clamp down yet harder. You taste blood through them.
                                
                                [i]eat. eat. eat.[/i]
                                
                                Again you attack, aiming a punch at Surpass's head, connecting—and your hand rebounds in a burst of pain, like you just punched a brick wall. Suddenly, the nodes can't break skin any longer, scrabbling ineffectually at the hero's wounds.
                                
                                Surpass straightens, glaring at you. "Alright. Done with this BS. Hope you're ready for the beating of your life, Creepy—"
                                
                                *set stillnodes true
                                *goto architectploy
                            *else
                               *set nodedesc 3
                               *set nodecrushed true
                               It takes a moment to steady yourself from the force of the blow, a moment longer to start quelling the tremors in your body. Focus doesn't come easily.
                                
                               [i]eat. feed. eat.[/i]
                                
                               Surpass can't quite get a grip on any of the nodes, slippery and tenacious as they chew at her flesh. It's an opening.
                                
                               You advance into range—too slow, dammit—and lead with a strong overhand punch. Surpass sees it coming late, but still twists enough to one side that you only land a glancing hit.
                                
                               [i]bite. feed. eat.[/i]
                                
                               The nodes continue swarming over Surpass, and you press the attack, stringing together a combination of punches that drives Surpass back a step. Even so, you're struggling to deal significant damage, and your attempt to follow up is met with a blindingly fast front kick that sends you reeling. Surpass's hand moves just as fast, snatching one of the nodes and ripping it free.
                                
                               *label nodecrush
                               [i]prey. bite. e—[/i]
                                
                               Surpass crushes the node in her fist, and you involuntarily scream, clutching at your head as the feedback of its demise crashes into your system.
                                
                               [i]pain. gone. pain. pain. gone. flee.[/i]
                                
                               Alarm flies across Surpass's face at your reaction. The other nodes leap clear of her, rushing back to cling fearfully to your legs.
                                
                               *goto architectploy
                        #Use the distraction to retreat and regroup.
                            *if mc_health =1
                                Conveniently, that last kick from Surpass opened up a fair bit of space. You simply back up even further while trying to massage the feeling back into your arm. Given the pins and needles shooting through you are the result of Surpass barely making an effort, you're very confident that getting some distance is the correct decision.
        
                            *else
                                You scramble back along the floor until you've gained enough distance to lurch unsteadily back to your feet. It's not particularly dignified, but it gets you away from any more super strength knuckle sandwiches.
                                
                            [i]feed. eat. bite.[/i]
                            
                            Meanwhile, the nodes continue swarming over Surpass, snapping and tearing. Crucially, they prevent Surpass from pursuing you at least for a moment.
                            
                            *label goawaynodes
                            "Ugh! Will you things fuck off!?" 
                            
                            Surpass's hand suddenly lashes out with blinding speed, snatching one of the nodes off of her and raising it aloft.
                            *label justsaynerd
                            
                            "Hey, Creepy! Got your gross… pet… organ… thing!"
                            *fake_choice
                                #"Put it down."
                                    Surpass's eyes light up. "Oh, is it important? I sure hope so." 
                                #"Node."
                                    "Did you just call me a nerd?"
                                    
                                    Your membrane makes your stare blank by default, but this one is especially so.
                                    
                                    Surpass shifts awkwardly. "Look I thought you said—ah screw it."
                                #Shrug.
                                    "Oh, in that case…"
                         
                            *if mc_health =1
                                *set nodedesc 3
                                *set nodecrushed true
                                *goto nodecrush
                            *else
                                *set nodedesc 2
                                *set nodecrushed true
                                *goto nodecrush
                         
                    
                *else
                    After the exertion of creating the nodes, you're far from full strength, and your punches are much more sluggish than usual. Surpass blocks the next two strikes, and then counters, throwing out a side roundhouse kick almost lazily.
                    
                    Though you manage to guard yourself, the impact is anything but lazy. It lands like a hammer, sending you staggering several steps to just barely maintain your balance. 
                    
                    Surpass snorts. "Least you didn't fall on your—agh!" A node pounces onto her with a surge of predatory instinct. "Get the hell off!" You feel the excitement and bloodlust of scenting prey, and the other nodes leap onto her in turn.
                    
                    [i]bite. tear. eat.[/i]
                    *goto surpassnodes
            #Send in the nodes first, and then strike while she's distracted.
                Controlling the nodes is more art than science. Despite being a part of you, they're very different from the tendrils, and can't simply be moved like any other limb. They're a pack of unruly dogs with whom you happen to be mentally linked.
                
                [i]eat. feed. bite.[/i]
                
                On the positive end, they hardly require much of a push to attack the closest person. The trio immediately rushes at Surpass, scurrying on their spindly dendrites to leap at her and latch on, clinging and biting. You hang back, biding your time as you taste blood through them.
                
                "Agh! Get the hell off!"
                
                [i]prey. hunt. eat.[/i]

                *if fighting_style =2
                        You have to close your eyes for a moment, rocking with the intensity of the nodes' emotional feedback. Only by concentrating on your training are you able to shake it off and refocus. Using your head, just like you were taught.
                        
                        *goto nodesgood
                *elseif expressive < 60
                        Fortunately, you're reasonably good at remaining calm, and the intense emotional feedback of the nodes is something you're able to block out with a little effort.
                        
                        *goto nodesgood
                        
                *else
                    *set expressive -5
                    The problem with relying on the nodes like this is the intensity with which they feel.
                    
                    [i]bite. feed. bite.[/i]
                    
                    As a person who tends towards exuberance, it's very, very difficult to shut out the thrill racing through the nodes and straight back into your system, building to a fever pitch.
                    
                    You don't want a vicarious experience. You want it for yourself.
                    
                    [i]prey. bite. feed. feed.[/i]
                    
                    Suddenly, you're charging at Surpass, desperate to join the frenzy. You'll bite. hunt, feed, eat—
                    
                    You don't begin to pick the moment correctly. Surpass sees you coming a mile away and answers your rush with a boot, instantly dropping you to the floor to think about your life choices and general lack of self-control.
                    *choice
                        #Try to scramble an improvised defence.
                            You spring back up to your feet and shake off the cobwebs.
                            
                            *if instinctive > 60
                                Surpass takes the opportunity to go after you, swinging for the fences. You duck on instinct and punch her in the kidney.
                                
                                "Son of a—"
                                
                                [i]bite. eat. feed.[/i]
                                
                                Now that you're involved in the fight directly, it's a little easier to tune out the nodes, which continue gnawing away at Surpass while you remain evasive and throw out the occasional strike.
                                
                                *goto goawaynodes
                            *else
                                *set instinctive +3
                                Improvisation! You are good—okay decent— okay not the greatest at that.
                                
                                Uh oh.
                                
                                Surpass goes after you, swinging for the fences. You manage to duck, but your counter attack is limp. Surpass shrugs it off.
                                
                                [i]bite. eat. feed.[/i]
                                
                                She looks distracted by the nodes, and you snatch at the chance too eagerly. She moves, turning your haymaker into a glancing blow, and then headbutts you with crashing force.
                                
                                Needless to say, you're on the ground in short order. At the corners of your awareness, you feel Surpass rip one of the nodes clear.
                                
                                *set surpass_fight 3
                                *goto justsaynerd
                        #Think this through and come up with a new plan.
                            Clambering back up to a vertical base, you take deep breaths, attempting to reassert control.
                            
                            *if instinctive < 40
                                Calm falls over you as you push the nodes' instincts out of your mind. You might be in touch with your emotions, but you know how to take things step by step too.
                                
                                Right now, the priority is to not get knocked the hell out, and that's where you place your focus, carefully backing up and keeping Surpass at arm's length. If you keep delaying her, the nodes will wear her down.
                                
                                [i]eat. tear. bite.[/i]
                                
                                *goto goawaynodes
                                
                            *else
                                *set instinctive -3
                                Unfortunately, slowing things down isn't really your strong suit. Though you try to plan, your concentration is continually broken by Surpass's attacks, and in spite of yourself, you wind up drawn more and more into desperate defence rather than thinking the problem over.
                                
                                It's only a matter of time before Surpass's fist comes crushing through your block, and the follow-through knocks you to the ground.
                                
                                [i]bite. feed. eat.[/i]
                                
                                You feel a node squirm as Surpass rips it clear of herself. The others nip and gnaw, but it's too little too late.
                                
                                *set surpass_fight 3
                                *goto justsaynerd
          
                *label nodesgood
                That brief storm weathered, you focus on your goal. Surpass is struggling to handle the three bundles of flesh and teeth scrambling over her body, but they aren't chewing their way to victory any time soon; the nodes are more piranhas than sharks.
                    
                Still, you wanted a distraction and Surpass looks thoroughly distracted. Time to move.
                    
                [i]bite. prey. eat.[/i]
                    
                Surpass is partially turned away, and doesn't see you coming in the slightest. You land a punch clean to her ear, following on with an uppercut lunge that snaps her head backwards and sends her staggering.
                    
                [i]eat. eat. feed.[/i]
                    
                The nodes thrill with delight, clamping even harder—then can bite down no longer. Surpass's skin almost seems to repel their teeth, which can no longer gain purchase. You swing another punch into her jaw, and it's like striking a brick wall.
                *choice
                    #Okay, change of plan. I'm going defensive.
                        You can't tell what just happened. Surpass is supposed to be durable, but how did her resilience suddenly spike like that? You're instantly on the back foot, and you don't even know what changed.
                            
                        [i]bite. tear. eat.[/i]
                            
                        Retreating a step, you pull back out of Surpass's reach and consider your play.
                        *choice
                            #Stall. I'll improvise.
                                *if fighting_style = 2
                                    Adapting on the fly is exactly your speciality, so why stop now? You just have to roll with the punches and figure something out.
                                        
                                    Architect said to hold Surpass off, not to beat her. You don't have to win.
                                        
                                    "I have you right where I want you!" you call out. Surpass pauses in her advance. "The venom is already in your system."
                                        
                                    *label stallsuccess
                                    *set surpass_fight 2
                                        
                                    Surpass shakes her head with a snarl. "You're getting on my nerves, creepy."
                                        
                                    Maybe, but she's preoccupied. Subtly, you call the nodes back, and Surpass startles as they detach and scurry back to you.
                                        
                                    [i]eat. feed. prey.[/i]
                                        
                                    "Shouldn't have let me bring these back," you tell her. "Now I—"
                                        
                                    *goto architectploy
                                       
                                *elseif instinctive > 57
                                    You let the nodes do their own thing and dart back into range. Surpass takes an immediate swing, and you duck beneath it, dodging behind her. There's no intention of landing a strike of your own, you're just keeping her busy.
                                    
                                    She growls in frustration as you continually evade her attempts to hit you, relying on instinct to keep out of trouble.
                                        
                                    *goto stallsuccess
                                *else
                                    *set instinctive +3
                                    Right. Improvising! You can do that. Now you just have to think of a plan—or wait, should you be planning at all—?
                                        
                                    Indecision hits you. A second later, Surpass also hits you. Weird how that works out.
                                        
                                    Stumbling back, you shake your head, attempting to clear the cobwebs. Surpass is not nearly so generous as to give you time to recover, and presses the attack. You try to let go of your thoughts and just concentrate on defence; the problem is, well. You're not very good at that.
                                        
                                    Surpass slams an elbow into your face and you hit the deck. Hard.
                                        
                                    *label failuretime
                                    [i]bite. eat. bite.[/i]
                                        
                                    You feel her hand wrap around a node and rip it clear as it squirms.
                                    *goto justsaynerd
                            #Fight, but be careful about it.
                                *if fighting_style = 1
                                    Although Muay Thai is an aggressive style, having hand-to-hand expertise is enough to let you protect yourself.
                                    *label carefulsuccess
                                    *set surpass_fight 2
                                        
                                    Surpass goes on the offence, and you focus on keeping her contained. Strangely enough, the strikes that you block, deflect, and avoid seem to have less force behind them than before. On the other hand, checking her attacks now feels like you're parrying iron bars. What on earth is she made out of?
                                        
                                    [i]prey. hunt. bite.[/i]
                                        
                                    The nodes, apparently growing bored of prey they can't chew upon, detach themselves and return to you.
                                        
                                    Surpass studies you for a moment. "You're pretty good, creepy," she says begrudgingly. "But I'm just getting—"
                                        
                                    *goto architectploy
                                *elseif instinctive < 43
                                    One step at a time. That's usually the type of cautious approach you favour.
                                        
                                    *goto carefulsuccess
                                *else
                                    *set instinctive -3
                                    Okay! One step at a time! You can… alright wow that's really not your normal MO, is it?
                                        
                                    Surpass goes on the offence, and though you try to stick to the plan, it's a real challenge to keep yourself from seizing on any apparent openings. The second there's a gap, you have to restrain your automatic urge to strike.
                                        
                                    Thanks to the lapses in concentration, your defences suffer, and suddenly Surpass's elbow slams into your face. You hit the deck, hard.
                                        
                                    *goto failuretime
                            
                    #I just need to find the right angle for the nodes.
                        Surpass's sudden spike in durability isn't insurmountable, provided you can nudge the nodes out of blindly biting themselves to death.
                            
                        *if fighting_style =3
                            *set surpass_fight 2
                            During training, you've dabbled with tightening the nodes' collective leash. Creating them is just too exhausting to regularly practice, but you think you've built up enough of an understanding to fine-tune your control now.
                                
                            You apply every ounce of concentration towards your link with the nodes. It's less a matter of instructing them directly, more planting [i]ideas[/i] and [i]impressions[/i] of what you want them to do. Sure enough, the nodes respond, their urge to bite dampening as they instead crawl further up Surpass's body.
                                
                            [i]Move. Hunt. Prey.[/i]
                                
                            They manage to squirm their way into position around her shoulders to restrict her movements, the most adventurous of the trio grasping at Surpass's neck; it has no more luck constricting her throat than it did biting, but the furious and frustrated expression on Surpass's face is plain as day.
                                
                            "Wow, creepy, you've got to be one of the most annoying, grossest people I've ever fought." Her voice is far too strained for you to give credence to any attempted levity.
                            *fake_choice
                                #I can't spare any concentration for banter.
                                    You're just about keeping the nodes under control right now.
                                    
                                #I can't spare any concentration for banter, but I can look smug.
                                    Though you're just about keeping the nodes under control, you can always spare a mote of concentration for taunting.
                                        
                                    *if expressive > 57
                                        Your face isn't visible, but you certainly [i]convey[/i] smugness with your demeanour. Surpass glowers, and you know you've scored a point.
                                            
                                    *else
                                        *set expressive +1
                                        Unfortunately you don't have a visible face, so your attempt to convey smugness through demeanour alone is rather lost on her. 
                                        
                                #"One of? How do I get the top spot?"
                                    Surpass laughs in spite of herself, which is just as well, since your switch in focus provokes a fresh wave of intent from the nodes. You hasten to reassert  control before they bite her.


                            In any case, you find yourself stalemated. Your nodes can't really inflict further damage to Surpass, but they're inconveniencing her enough that you're sure that you can evade her clutches for a good long while.
                                
                            [i]Stay. Keep. Prey.[/i]
                                
                            Surpass seems to recognise the impasse the same as you, glaring in your direction while occasionally attempting to swipe a node clear, and getting eluded for her troubles.
                            *set stillnodes true
                            *goto architectploy
                                
                        *else
                            *set surpass_fight 3
                            You concentrate on your link with the nodes and start broadcasting instructions. Move here. Grab there. Don't bite, constrict.
                                
                            [i]bite. prey? feed.[/i]
                                
                            Muddled confusion rushes back to you, and the nodes wriggle indecisively. One attempts to gnaw at Surpass again, and its teeth crunch to pieces.
                                
                            Your legs wobble. You push through the exhaustion and try the commands once again. The nodes won't—perhaps can't—listen.
                                
                            [i]eat. bite. bite.[/i]
                                
                            With the trio's chewing and scrambling proving completely ineffectual, Surpass is now very much undistracted. You're so preoccupied with forcing your will upon the nodes that you don't realise she's charging until the last second. Your attempted dodge comes too late. Surpass nails you with a left hook so brutal, the next thing you know, you're face down on the ground.
                                
                            "Not gonna lie, Creepy." Surpass says conversationally from somewhere above you. "That one felt pretty good."
                                
                            Dimly, you sense the nods abandoning their efforts and scrambling back towards you with something approximating concern.
                                
                            Great. [i]Now[/i] they care about you. So touching.
                            
                            *goto architectploy
                    

                            
    #Inducing wild mutations of my body.
        *set speciality 2
        *set juice -40
        *set snick "Chompy"
        Fuck, but you hate doing this.
        
        You extend your senses fully into your tendrils and the inky coating of your upper body. You can taste the air through the tendrils, feel the sensation of the covering from both it and your skin. The connection is intimate. It's all part of you.
        
        Then you release all control, all at once.
        
        The result is instantaneous and explosive. One tendril surges in length and thickness, splitting in half with a guttural growl from its fresh formed mouth, filled to the brim with teeth. Bones shudder and warp, your right hand extending and fingers merging until your arm—itself swelling and twisting—is capped by two huge talons. Your body convulses, the black coating spreading down from your shoulders, covering your torso, which cracks open with yet another maw. A spike of agony hits you square in the head and you scream, blinded by the affliction of a distending, stretching skull.
        
        After an eternity, the pain recedes. It's over. You open your eyes. Singular on your head. The half dozen others dotting your body.
        
        Surpass takes a step back. "What the fuck." Her voice is hushed.
        
        The new form has power. You need only block out the dissonant sensations.
        *choice
            #Using these enhancements, I can stand up to her in a brawl.
                That's the point of letting your power off the leash like this, but just because the form is more monstrous, it doesn't mean that you have to fight like an animal.
                
                You charge Surpass, trying to catch her while she's still rattled by your transformation. Your legs tense and you spring into a leap. She ducks, dodging by a whisker, and you fly past. You ground your talons, arresting your momentum as they screech along the floor, allowing you to twist back around to face Surpass again.
                
                "Okay sure," she says, shaking her head sharply as if to clear it. "Guess you're some kind of monster… thing." She raises her fists. "Whatever. Hitting you now."
                
                *if expressive > 60
                    You let her know what you think of that with a snarling growl.
                    
                *else
                    Fine. Bring it on.
                
                Once more you advance, and this time, Surpass is there to meet you. 
                
                *if instinctive > 60
                    Soon, you find yourself with a problem.
                    
                    With each clawed swipe and tendril bite, the disconnect between your body and mind grows wider. Nothing is where it should be. You see from multiple perspectives at once. You want to sink your teeth into her, but which set of jaws?
                    
                    The instincts war with one another, and it's disorienting beyond belief.
                    
                    A vicious rake of your talons should sink home, but instead is so far off you leave yourself open.
                    
                    Surpass punches you in the mouth. The torso mouth.
                    
                    It's like getting chopped straight in the throat. Your whole body judders.
                    *choice
                        #Bite her.
                            *set surpass_bite true
                            Hey, she narrowed down the jaws for you.
                            
                            Your torso momentarily splits, and then your teeth crunch onto Surpass's extended arm.
                            
                            There's a second of still silence. Her eyes flicker from you to her trapped arm, buried to the elbow in your chest. You taste blood.
                            
                            The quiet ruptures.
                            
                            "What the fuck!? What the fuck!" Her frantic yelling is equal parts confusion and fury. Surpass wildly swings her free arm, punching you repeatedly in the gut while you wrestle to keep her at bay, clamping with your teeth and pushing with your tendrils.
                            
                            Swearing up a storm, Surpass suddenly grabs a tendril, swings you around, and then jumps up and drives both feet into your torso in an explosive kick. The force is too much for you to handle and her arm pops free, streaked with bloody gouges.
                            
                            You each retreat a couple of steps, Surpass cradling her injured arm.
                            
                            She catches your eye, scowls, and then extends that same arm, along with her middle finger. "Fuck you."
                            
                            *goto architectploy
                        #Bear hug.
                            *if mc_health > 1
                                *set mc_health +1
                                *set mutationdesc 3
                            *else
                                *set mc_health +1
                                *set mutationdesc 2
                                *set injurydesc 9
                            You surround her with tendrils, your oversized talon arm, your regular-yet-still-misshapen arm, clamp down, and begin to squeeze, crushing the air from her lungs.
                            
                            Her arms pinned by her sides, Surpass can't do much of anything about it.
                            
                            You're nose to massive-eyeball, seeing the strain in her face, the intense focus in her eyes.
                            
                            So close in fact, that in spite of her shemagh, you're able to tell from the twitch of cloth that she's smiling.
                            
                            "Didn't know… you felt this way… about me…"
                            
                            The last thing one of your bodily eyes sees is Surpass's fingers gouging into it.
                            
                            Howling in pain, you release her from the crush, and she drives a jumping kick into your chest, sending you crashing to the ground.
                            
                            "But sorry, Chompy, I don't have eyes for you."
                            *fake_choice
                                #Oh screw her.
                                    Bitch.
                                    
                                #Oh fuck her.
                                    Bitch.
                                    
                                #That would be funny if I wasn't in intense pain.
                                    Yeah this hurts far too much to laugh.
                                    
                            *goto architectploy
                            
                *else
                    Though your body keeps sending signals that don't match up with your mind's eye (such as the perspective of all those, well, eyes), you're able to shut out the disconnect. Sticking to a specific plan allows you to sharpen your focus, attend only to what matters. One step at a time. One punch after the next.
                    
                    Maybe one swipe after the next, in this instance.
                    
                    You rake Surpass's torso with your talons, turn your body to absorb the impact of her riposte, and then ram your maw-tendril into her face. She stumbles, looking stunned.
                    *choice
                        #Press the attack! I've got her!
                            Damn right you do!
                            
                            Leaping to engage, you aim another swipe of your talons at her. Surpass twists, and you score a jagged line down her arm. You lash out with the maw-tendril, and then Surpass suddenly isn't there.
                            
                            With literal eyes in the back of your head, you still barely see it coming.
                            
                            See, but don't react. Not quickly enough.
                            
                            Surpass clubs you in the spine, grabs a tendril at the base, and then uses it to drag you into a massive rabbit punch, right at the base of your skull.
                            
                            As your head snaps backwards, Surpass uncorks a thrusting kick to the small of your back. Simultaneously she releases the tendril, and you barely avoid front-flipping onto the ground.
                            
                            Instead, you stagger a few steps to regain balance, and then whip back around to face her.
                            
                            "What? Thought I was just gonna stand there and take it?"
                            
                            *goto architectploy
                        #Stay cool. No need to get carried away.
                            You play it safe and just give her a kick, knocking her away an extra step. Surpass staggers that bit further, but seems to get ahold of herself immediately afterwards. Hm. Quick recovery.
                            
                            *goto keepitcool
            #Rip and tear.
                Feral rage rushes into your system, your jaws—all of them—slavering and snarling. Your heartbeat thunders in your ears, each inch of your altered body thrumming with bloodlust.
                
                Roaring, you surge into the attack, taking a wild swing at Surpass with your talons. She evades by a whisker, but you continue on heedlessly, swiping and biting and tearing with tooth and claw. Your maw-tendril snaps hungrily and you lunge for Surpass's throat. She's forced to intercept with her forearm, and her blood bursts into your mouth as your teeth crunch down, sinking deep into her flesh.
                
                You howl triumphantly.
                
                *if instinctive > 60
                    There's a fine line to ride between tapping into this primal intensity and losing yourself within it. Fortunately, you're attuned enough to your own instincts to recognise that you're on the verge of teetering over that edge, and you haul yourself back.
                    
                *elseif fighting_style = 3
                    Tapping into this primal intensity isn't easy, but your keen understanding of your own powers allows you to ride the delicate line of wielding that strength and losing yourself to it. Your mind grasps your own reins, steering gently away from the rampage.
              
              
                *else
                    *set instinctive +5
                    Unfortunately, leaning into your instincts isn't your usual MO. With such primal intensity shaking you to your core, it's all too easy to give yourself over, lose track of your goals.
                    
                    You bite, and bite again, and slash with your talons, gouge and rip and kill and—
                    
                    Surpass's fist rams into your face with the force of a mack truck. You hit the ground so hard you bounce, managing to scramble onto your feet in the same breath.
                    
                    Though you've regained your footing, the same can't be said for your bearings. Snatches of feral thought race through your mind, and before you can sort through them, Surpass knocks you flat with a flying kick. You hear tiles cracking as she lands.
                    
                    Well. At least that rattled the monster out of you.
                    *choice
                        #I'm not done yet! Attack!
                            Slamming the ground with your remaining fist, you push yourself back up, ready for action.
                            
                            *if mc_health >1
                                *set surpass_fight 3
                                Until your body rudely reminds you of the punishment it has taken, and your legs buckle.
                                
                                Mutating doesn't fix your injuries, and now they're coming due.
                                
                                Triumph lights up Surpass's eyes as she surges forward and punishes the wobble with a sledgehammer of a right hand.
                                
                                You hit the floor even harder than before.
                                
                                "Start a ten count! It's over!" Surpass crows.
                                
                                As you twitch in your own personal crater, all three of your mouths combined can't muster a single counterargument.
                                
                                *goto architectploy  
                            *else
                                You launch yourself into combat once more, attacking with enough ferocity to drive Surpass back a step. Two. Three. She's stumbling, vulnerable—
                                
                                —and countering with a vicious right hand that sends you skidding, reclaiming all the ground you just won with a little extra on top. Damn but she's strong.
                                
                                Still, you're on your feet and uninjured, despite the massive power of that punch still careening through your bones. Your burst of offence worked as intended, though you don't feel any closer to seizing the initiative.
                                
                                As you consider your next move, a voice rings out.
                                
                                *goto architectploy
                        #I need to calm down and buy a moment to recover.
                            *if (fighting_style = 2) or (expressive > 40)
                                Fortunately, you're decent enough at keeping your emotions in check while thinking on your feet.
                                
                                That instinct to lunge straight at Surpass is still there, but you quell it, continuing to calm yourself.
                                
                                You pick yourself up off the ground, gears turning. Right now, you need space to breathe. Surpass is already bearing down on you, and certainly won't be so accommodating.
                                
                                Hm. You didn't notice earlier, too fixed on going beast mode, but you feel some kind of… gland in your maw-tendril's throat.
                                
                                You think that with a little effort you may be able to produce some manner of substance through it.
                                *choice
                                    #I probably shouldn't risk that.
                                        Yeah. Who knows what might happen?
                                        
                                        Instead, you make a show of rearing up as if to strike. Surpass halts, and you promptly leap backwards, clearing some distance.
                                        
                                        Surpass groans in frustration. "Now you're gonna make me run? Dick."
                                        
                                        *goto architectploy
                                    #It's worth a shot!
                                        *set surpass_douse true
                                        *set surpass_fight 2
                                        *achieve ewewew
                                        As you concentrate on the specific spot in your additional throat, your maw-tendril gapes open.
                                        
                                        Surpass's eyes widen at the sudden gurgle, and then deep red ichor sprays from the maw, dousing the hero from head to toe.
                                        
                                        She unleashes perhaps the loudest and most explosive string of profanities you've ever heard as the liquid clings to her.
                                        
                                        You observe her attempts to rub the ichor out of her eyes—it doesn't seem to have any adverse effects beyond being sticky and generally disgusting—and all of your mouths begin to grin.
                                        
                                        *goto architectploy
                            *else
                                *set expressive -3
                                *set surpass_fight 3
                                Calm. Calm. Calm.
                                
                                Okay, nope, as it turns out, just repeating the word to yourself over and over doesn't actually do much to calm you down. You're not good enough at rolling with the punches or checking your emotions to handle being so keyed up.
                                
                                Especially not when Surpass is on the attack the second you climb to your feet, and she has no intention of allowing you to recover.
                                
                                The best defence you can muster is an ineffectual and easily evaded swipe of the talons before Surpass cocks back a fist and hits you so hard that you spin 180 degrees en route to falling on your face.
                                
                                "Five points for style, Chompy. Zero for the landing."
                                
                                *goto architectploy
                
                You bite Surpass's arm once more for good measure, and then retract the maw-tendril before you overextend yourself. The hero's casual demeanour is long gone, replaced by sharp focus and determination. The scent of her blood permeates the air, but this isn't over yet.
                *choice
                     #I can finish her!
                        Your powers are more than a match for hers. You've proven it already.
                        
                        Forget holding her off, you're winning this.
                        
                        Once more, you lunge into the offensive. A rake of your talons scores vicious lines down Surpass's unbitten arm, and you let loose another howl as you snap your maw-tendril at her shoulder.
                        
                        Something crunches.
                        
                        You realise that it's your own teeth.
                        
                        Suddenly you're not biting into yielding flesh, but a slab of granite.
                        
                        What—
                        
                        "Snack time's over, Chompy!" Surpass prises the maw-tendril loose, and then punches you directly in the oversized eye on your face. You stagger backwards, clutching at your head.
                        *fake_choice
                            #Cry out.
                            #Swear.
                            #Remain stoic.
                                
                        "Did that hurt!? Good!"
                        
                        You glare balefully, wounded eye now forcibly narrowed. Surpass looks incredibly pleased with herself, even with bloody streaks running down both arms.
                        *goto architectploy
                     #Don't get carried away. She's dangerous.
                        You can keep yourself under control, and there's no reason to lose your head. Besides, Architect said to hold Surpass off, not beat her senseless.
                        *fake_choice
                            #I'm counting on him to have a plan.
                                He seems the type.
                            #I don't care to follow orders, I'm just being smart here.
                                Right. Architect can do whatever he wants.
                        
                        *label keepitcool
                        Studying Surpass carefully, you wait for her to make the next move.
                        
                        She huffs, and you can't tell whether she's annoyed or impressed. "Guess you're not as wild as you look." She raises her fists. "Alright, let's rock." Kicking off her back foot, she charges.
                        
                        You meet her attack with your overgrown shoulder. Though you check her momentum, you're still knocked back a step. Damn she's strong.
                        
                        Still, powerful as Surpass is, she's fighting injured. Each time you swing your talons or lunge with a bite, she's forced to pivot immediately to defence to prevent further damage. Your own caution means you have an eye—several, really—out whenever she tries anything, and you block or avoid her attacks.
                        
                        The two of you are evenly matched. This battle might come down to stamina alone.
                        *set surpass_fight 2
                        
                        *goto architectploy

    #Thickening my membrane into a true carapace. [Less body horror]
        *set speciality 3
        *set juice -40
        *set snick "Shelly"
        This will suck. Not once has it not sucked.
        
        Concentrating your control within the inky coating of your upper body, you push outward. Swiftly, you're 'rewarded' with the crawling sensation of the membrane trickling further down your torso. Simultaneously, the existing covering hardens, the growing weight pressing down upon your shoulders. Outwardly, you know that the inky, oily surface now begins to resemble a ridged shell, almost insectile in nature, including your head, crowned like a beetle. Nevertheless, it's no more of an impediment to your vision or hearing than before, despite the increase in bulk and heaviness. From a simple membrane to a flexible, highly fortified carapace.
        
        To be covered so far down your body is suffocating. Drowning. Sensations are amplified, feeling both the carapace on your skin and the skin on your carapace. And it never stops. At best, it fades into the background.
        
        You hate it.
        
        Surpass, by contrast, looks delighted. "Well that's cool as shit." Her eyes gleam with predatory intent. "Wanna bet I can crack it open?"
        
        Why are you not surprised she takes armour as a challenge?
        *choice
            #Engage with caution: I don't know how strong she truly is.
                You knew of Surpass before today, but you've never seen her in action. Super strength encompasses a wide variety of definitions, from the ability to bench press twice the regular amount to being capable of hurling trucks around like toys. Considering the ease with which Surpass ejected Wyrd, you're not taking any chances.
                
                Steeling yourself, you wait for Surpass to make the first move. You're not standing idle for long; she bounds towards you with all the enthusiasm of a great dane seeing its favourite toy.

                *if instinctive < 40
                    Choosing the right moment to act is fortunately your forte, and you don't allow the anticipation to affect your focus. You wait, holding your ground as Surpass gets closer and closer. Lowering her shoulder, Surpass slams into your braced stance like a battering ram. Even perfectly set, the impact sends you skidding backwards, but you maintain your footing and keep steady.
                    
                    "Huh. Alright. Not bad." Surpass rolls one shoulder, then the other. "Hope you aren't just gonna stand there, shelly."
                    
                    *choice
                        #I fully intend to just stand here.
                            *if expressive > 60
                                You give her a jaunty little shrug.
                                
                            *elseif expressive < 40
                                You remain impassive. Motionless.
                                
                            *else
                                You flex your wrists, maintaining your stance.
                                
                            Surpass groans. "Got it, you're boring. Whatever."
                            *fake_choice
                                #She can complain if she likes. I don't care.
                                    If she wants to be entertained, maybe she should go buy a movie ticket.
                                    
                                #I'm taking a little satisfaction from getting under her skin.
                                    Getting a rise out of her just by being a problem she can't punch feels pretty good.
                                    
                            Regardless, if Surpass wants to fight, then it'll be on your terms, and you're not budging.
                            
                            The hero shifts her weight, then shows off her footwork with a couple of quick stance swaps.
                            
                            Very, very quick.
                            
                            Surpass blurs, and before you can fully register it she's on top of you, firing off barrages of punches that you can barely see, let alone block. You're forced to give ground, then again, and again, until you're almost in full retreat.
                            
                            After a stinging uppercut to your chin, Surpass springs backward, watching you with obvious glee in her eyes.
                            
                            "C'mon, shelly. Give me some credit, yeah?" She shadowboxes, hands moving like lightning.
                            
                            *goto architectploy
                        #I have her measure. I can go on offence.
                            *set surpass_fight 2
                            You can't stay static, not against an opponent on Surpass's level.
                            
                            Advancing, you take a hard, pounding shot to the carapace before throwing a strike of your own, which Surpass blocks ably. Then you're at it in earnest. Attack. Defend. Attack. Defend.
                            
                            Surpass is faster than you and lands more hits, but you've got your carapace to rely on, and even as those shots thunder into your armour, resounding like hammers to the anvil, the armour is equal to the task. By contrast, you aren't connecting as often, but each strike that passes her defences thumps home with authority.
                            
                            You're evenly matched. This might come down to stamina.
                            
                            Surpass's eyes are lively. She's enjoying the fight.
                            *fake_choice
                                #She's not the only one.
                                    *set expressive + 5
                                    A smile is slowly creeping its way across your face.
                                    
                                #I'm staying focused.
                                    *set expressive - 5
                                    This is serious. Enjoyment doesn't come into it.
                            
                            *goto architectploy
                *else
                    *set instinctive -5
                    Unfortunately caution doesn't always come naturally to you. Surpass is charging you down; maybe you shouldn't allow her to get up a full head of steam. Though you attempt to convince yourself that holding your ground is the right move, you react instinctively at the last second and try to meet Surpass with an attack of your own.
                    
                    The break in your defensive stance is punished instantly as she bulldozes straight through your lunge and straight over you, bodychecking you to the ground with a crash.
                    *choice
                        #Dammit! I'm being too passive. I need to fight her properly.
                            Clambering back to your feet, you take a moment to breathe, even as dread crawls down your spine.
                            
                            *if fighting_style=1
                                You know how to fight. There's no need to turtle up.
                                
                                *goto carapacefighting
                            
                            *else
                                Okay. Okay. You can do this.
                                
                                *goto carapacelosing
                                
                        #Defend! Defend!
                            You scramble to your feet and try to reset.
                            
                            *if fighting_style =2
                                First thing's first. Getting frantic isn't going to help. You quell the panic bounding around your head and concentrate.
                                
                                Alright. She's fast. She's strong. That means protecting yourself properly and sticking to a plan.
                                
                                The Surpassdozer is incoming. You dive to the side, tucking and rolling back to your feet.
                                
                                But plans can be flexible. Having your carapace doesn't mean just standing around. You're still plenty mobile.
                                
                                Your movement seems to catch Surpass off guard, and she's slow to wheel back around. In that delay, you close the gap, hitting a quick one-two of body shots before disengaging.
                                
                                That's about as much offence as you're going to get for now; Surpass is right back at you and throwing bombs like they're going out of style. You cover up intelligently and back up where you need to, and most of her attacks don't break through your guard. Though even those that don't are like hammers on your carapace, impacts ringing around your whole body.
                                
                                You're still losing, just more slowly.
                                
                            *else
                               *set surpass_fight 3
                               Block—wait no, retreat. Hold on, maybe you should—
                                
                               The Surpassdozer runs you over again. You can't stop the panic rebounding around your head and it makes you clumsy and uncoordinated. This time, you don't even manage to rise before Surpass comes in for another assault.
                                
                               Her kick smashes into you, sending you skidding across the floor so hard you leave a furrow of shattered tile.
                                
                               "You make a great pinball, shelly!" she calls. "Might be a good career for after you get out of the slammer!"
                                
                            *goto architectploy
            #I'm taking that bet and fighting her directly.
                Wyrd managed to soak a hit, and your carapace always held up fine against the no-punches-pulled assaults in your training. As strong as Surpass is, that strength surely can't be limitless. So, if that's where she wants to take this fight you're willing to oblige. 
                
                You both advance at once, meeting in the middle with an explosive exchange of blows. You bring hardened fists to bear, driving them with all the force you can muster. Her strikes thunder into your carapace, resounding like hammers to the anvil.
                
                *if instinctive < 40
                    *set instinctive +5
                    In theory, you know that you should be able to rely on the armour to protect you. In practice, the repeated impacts fray at your nerves. The more you think about your defensive shell, the more narrowly you concentrate on the sensations of being struck. You can feel fractures beginning to form beneath the surface, how each new hit warps and damages the integrity of the structure that bit further.
                    
                    You can't disengage your brain for long enough to maintain your own offence, and you soon find yourself turtling, focusing on your own protection to the exclusion of anything else. It's not tenable, and Surpass soon slips past your block to land a hard body shot with a gunshot-like [i]crack.[/i]
                    
                    "Ha! Call that another win for Surpass!"
                    
                    The pain of the rupture in your armour is only a little less potent than the intense dread pooling in your gut.
                    *fake_choice
                        #I need to stop relying on my carapace and just fight.
                            *if fighting_style =1
                                Right. Leaning more extensively on your powers doesn't throw the rest of your training out of the window. Accentuate, don't replace.
                                
                                *label carapacefighting
                                Shaking off the rising panic, you raise your hands to shoulder height, lifting one foot slightly.
                                
                                Surpass regards you curiously. "Dunno what kind of stance that is, but I'm game." She bursts back onto the offensive.
                                
                                Before she can close the distance, you repel her with a kick and then follow up, driving an elbow into her head. Surpass takes a second to shake off the cobwebs and the straight punch she throws connects with far less force than before. A roundhouse knee lands with authority, and you press your sudden advantage.
                                
                                Or try.
                                
                                Surpass suddenly moves with blinding speed, dodging your attack and then unleashing half a dozen punches in the blink of an eye, right into the crack in your carapace. Each individual strike isn't close to as strong as her previous sledgehammers, but combined you feel something in the membrane give with a wet crunch.
                                *fake_choice
                                    #Cry out.
                                    #Swear.
                                    #Remain stoic.
                                
                                Surpass pulls back her hand, now slick with black ichor. She stares. "Uh… really hope this isn't your stomach blood, shelly."
                                *set mc_health 2
                                *set injurydesc 4
                                *goto architectploy
                            *else
                                *label carapacelosing
                                *set surpass_fight 3
                                *set mc_health 4
                                *set injurydesc 5
                                Though you try to shake off your rising panic, it latches its claws into you ever more insistently. Your armour can't hold up to her power, and it's supposed to be your trump card. How can falling back on normal combat techniques possibly be enough?
                                
                                No. You can't let doubt drag you down.
                                
                                You engage, but your hesitant, tentative striking is easily blocked or dodged by Surpass, who chuckles all the while.
                                
                                "Yup, that's the problem with relying on armour, shelly…" She catches your swing midflight, then hauls you in close. "One crack, and everything falls to pieces."
                                
                                Surpass grabs you by the carapace, lifts you bodily in the air, and then plants you to the ground with boneshaking authority.
                                
                                "Start a ten count! It's over!" Surpass crows.
                                
                                Sprawled in your own personal crater, carapace shattered around you, it's hard to muster a compelling counterargument.
                                
                                *goto architectploy
                        #Change of plan: All my energy goes to shoring up my carapace.
                            If the shell can't hold up in a straight fight, then you're screwed.
                            
                            Looks like the best defence is a really, really good defence.
                            
                            You recentre your control over your power and with a sharp breath, slam everything you've got into the carapace.
                                
                            Instantly, your power responds. Layers thicken, new plates forming on top of one another as the armour becomes even sturdier.
                            
                            *if fighting_style =3
                                Sure, it's heavier, but your grasp over your powers is firm. You ensure the structure is sound, and that prevents the weight from becoming overbearing.
                                
                                By the time Surpass charges in for her next attack, the punch is less hammer to anvil, more fist to brick wall.
                                
                                She steps back, shaking her hand. "O…kay." After a second to massage her knuckles, she focuses back on you. Her eyes are gleaming. "Double or nothing?"
                                
                                *goto architectploy
                            *else
                                *set ohgodarmour true
                                *set surpass_fight 3
                                It's also heavier. Much heavier.
                                
                                Too heavy.
                                
                                You realise your mistake too late and have no opportunity to correct it before Surpass charges in for her next attack. Your balance is entirely off, and though the bolstered carapace shields you from the blow, the force still sends you crashing onto your back.
                                
                                *if mc_height = 2
                                    Surpass's laughter rings out. "That armour a little too big for you, shelly? Maybe they have it in kiddie sizes!"
                                    
                                *else
                                    "No dice, Shelly!" Surpass calls out. "If that was supposed to be double or nothing, you should probably fold before you lose your shirt!"
                                    
                                *goto architectploy
                *else
                    You tune out the impacts. You tune out everything. There's just you, Surpass, and the fight.
                    
                    Freed from worry about protection, you're able to divert all your attention and energy to offence. Your all-out assault drives her back, and back again, until she suddenly disengages from you entirely, leaping out of range.
                    
                    Landing lightly, Surpass laughs and shakes her head. "Damn, Shelly. Guess you win the bet."
                    
                    *if expressive > 60
                        You find yourself grinning, and tap your chest in a 'come and get it' gesture.
                        
                    *else
                        You stay focused, and simply rap your armoured fists together.
                        
                    Surpass cracks her knuckles, eyes fierce and lively. "No biggie. Keeps it interesting."
                    *choice
                        #If she's still this confident, she must have something up her sleeve.
                            Yeah. Taking her lightly would be a horrible idea. She isn't limited purely to super strength.
                            
                            And as that thought runs through your mind, Surpass blurs into motion. You throw up your defences at the very last instant, parrying a punch so fast you barely see it.
                            
                            There's the speed—
                            
                            Avoiding the sucker punch gives you just enough of an edge not to get utterly rocked by the lighting quick flurries of blows that now come your way. You can't block all of them, or even most of them, but they also aren't landing as hard as some of her previous shots. More speed and less power.
                            
                            Surpass doesn't just stand toe to toe. She blurs around you, hitting from behind, the side, high and low. Your carapace is holding up, but how long can that last under such an onslaught?
                            
                            *goto architectploy
                        #Surpass is bluffing. I won't second guess myself.
                            If her capital S Super Strength can't break through your armour, then how exactly is she going to beat you?
                            
                            Not by psyching you out. Not if you have any say in the matter.
                            
                            You resume your advance, keeping your fists raised. Alright. Next verse, same as the first.
                            
                            Surpass, though, has an alternative verse in mind. Maybe a separate track entirely.
                            
                            As you get into close quarters, fully expecting more hammer blows from Surpass, you throw a punch and miss. And miss. And miss.
                            
                            She's suddenly moving far too quickly, and no amount of instinctual brawling is enough to land a hit on her. Instead your head snaps back, drilled by a lightning-quick jab. Then she vanishes from in front of you in a blur, and there's no opportunity to even look for her before she sweeps your legs out from behind you and you crash to the ground.
                            *fake_choice
                                #Uh oh.
                                #Dammit!
                                #Tch.
                                    *set expressive -1
                                #Fuck!
                                    *set expressive +1
                                    
                            You react without thinking, rolling hard to your left. It's just as well you do, because a punch still glances off the side of your head.
                            
                            With just about enough separation, you scramble to your feet, searching around for Surpass.
                            
                            She's standing opposite you, bouncing on the balls of her feet and, while you can't see behind her mask, you're absolutely convinced she's grinning.
                            
                            "C'mon, shelly. You really thought that was everything in my bag?"
                            
                            *goto architectploy
*label architectploy

"If I could have a moment of your attention…"
*page_break Architect's voice.

*if surpass_fight = 3
    You barely manage to turn your head towards the sound.
*else
    You and Surpass both turn towards the sound.   

Architect stands atop a pyramid of energy. Through the translucent blocks forming the structure below him, you see trapped within not only Arcade and Enfilade but also an ordinary man in businesswear, wide-eyed with terror.

*if (stillnodes)
    Surpass freezes. You take the opportunity to surreptitiously command the nodes to return. They detach from her and scurry back to you, clinging to your legs.

*else
    Surpass freezes.

"Good afternoon, Surpass. I'm sure you can gather the implications of my display here."

"What. Do. You. Want?" Surpass snarls.

Architect inclines his head. "It's simple, really. Allow my associates and I to walk free, and no harm will come to any of my guests. Otherwise…" He twists a wrist and a tremor runs through the entire structure.

"Yeah? And what happens if I punch your teeth down your throat first?"

"A total collapse."

Surpass glowers.
*fake_choice
    #That's cold blooded.
        Unease trickles down your spine. Holding hostages is ruthless enough, but if Architect actually means what he's saying…
    #I'm in dangerous company, clearly.
        This was never going to be fun and games, but Architect just ramped the situation to a whole new level.
    #He understands 'any means necessary'. I'm the same way.
        You can't fault him for this. Surpass isn't a problem you can handle with brute force: @{surpass_fight you were barely clinging on|you were just about fighting evenly, and it could have gone either way|she already beat you down thoroughly}. That means using any and every tactic, even if they're ruthless.

"Rest assured, Surpass. This dissipates the moment I reach a safe distance."

The hero laughs bitterly. "Guess I don't have much of a choice." She thrusts a finger at Architect. "But next time I see you, I'm snapping you in half. Worse, if you're lying."

*if surpass_fight < 3
    "Noted." Architect descends his pyramid at a trot. "Come along, both of you."
    
    Wyrd reappears, seemingly no worse for wear from their brief trip with Air Surpass. They stroll up to your side, sticking both hands in their pockets.
    *fake_choice
        #"Good to see you're alright."
            "Psh, you think I'd go down that easy? No way."
            
        #"I wasn't expecting you to be up and moving already."
            "I'm the resilient type." They chuckle to themself, apparently pleased with some private joke.
            
        #Give them a nod.
            Wyrd winks in response.
            

*else
    "Noted." Architect descends his pyramid at a trot. "Wyrd, please assist our associate."
    
    "Sure thing." You hear footsteps, and then Wyrd's voice again, much closer than before. "Easy does it." They help you up to your feet, making a show of dusting you off. "Hey, don't worry about it, I got bodied too."
    *fake_choice
        #"Thanks I guess."
            "Remember, it's all part of the process."
            
            You're not sure what process they're talking about.
            
        #"I didn't get bodied."
            Wyrd laughs. "Sure thing, champ."
            
        #Don't say a word.
            "Aw, no need to get all broody over it."
            
Together, the three of you hustle out of the building and into a wide alleyway, leaving the glaring superhero behind. Architect takes an immediate left, his stride gaining pace. @{mc_height DUMMY|You're a fair bit shorter than him, and have to hurry to keep up.|You're shorter than he is, and have to speed up to match him.|Thankfully you're a similar height to him, and keeping up is manageable.|You're taller than he is, allowing you to keep up without too much extra effort.|Since you're much taller than him, lengthening your stride a little is enough to match his speed.} @{ohgodarmour Your armour's weight hangs oppressively on your shoulders, and with what attention you can spare for your powers, you try to pare the carapace down to a more manageable size.|}

"Follow me."

Architect leads you around a corner, and then breaks into a run. It's early afternoon and though there are plenty of people out on the streets, the path ahead of you clears in a hurry. When it comes to parahumans, nobody's eager to make themselves a martyr.

The course Architect charts is circuitous but unerring, making twist after turn after twist until the three of you leave the hubbub of downtown Alderbrook behind. You're unfamiliar with this area of town, though between the boarded up windows and lack of foot traffic, you suspect it's the kind of neighbourhood whose residents don't ask questions.

*page_break

*if (mc_health >1) or (surpass_fight = 3)
    After so much exertion, your injuries are beginning to take a real toll on you. There hasn't been a spare moment to tend to them, and resilient as you are, you can't keep this up indefinitely.
   
*elseif speciality = 1
    Between racing around, the fight, and the toll of producing the nodes@{nodecrushed —not to mention Surpass crushing one of them—your| your} vision is greying around the edges from exhaustion. The nodes cling to you, quieted by your fatigue.
    
*else
    Although you made it out of the fight relatively intact, you're beginning to flag a little at this point.
    
    
Turns out that training for a superpowered brawl is a far cry from the real thing.

Wyrd glances at you. "Hey, hang in there. Just a little further."
*fake_choice
    #"How little is little?"
        "Very."
        
        …You're not sure what you expected.
    #I nod wearily.
        They give you an encouraging smile.
    #"I'm fine."
        They click their tongue. "If you say so."
    *if (speciality =1) #I try to push through the haze.
        You take a faltering step, catching yourself on the closest wall. The nodes shift uneasily.
        
        Wyrd starts towards you, readying to keep you upright, but you regain your balance and straighten up.
    *if ((mc_health >1) or (surpass_fight = 3)) #Honestly, I'm out on my feet.
        You begin to teeter. Wyrd steadies you gingerly.

Architect clears his throat. "Here." He gestures to a nearby doorway, outfitted with a sheet of chipboard in lieu of an actual door. Pushing the board aside, he ducks into the gloomy building beyond. Following him within, and then down a short corridor, you soon find yourself in a bare, unadorned room with a concrete floor. A naked bulb casts dim yellow light on the desolate surroundings.

"Now we can catch our breath," says Architect. His power produces a cube, which he promptly sits on. Wyrd seems content to lean on the wall.
*fake_choice
    #Sit on the ground.
        *set rel_wyrd +1
        
        You flop down with a relieved sigh. Finally off your feet. 
        
        What a day, and it's not over yet.
    #Remain standing.
        *set rel_architect +1
        You somehow doubt you're going to get much rest on barren concrete, but at least you're off the street and away from immediate pursuit.
    #Join Wyrd in leaning.
        *set rel_wyrd +2
        The corner of their mouth twitches up.
    #"Hey, could I get one of those?"
        *set rel_architect +2
        "I suppose." There's a faint note of amusement in Architect's voice as another energy cube rises from the ground.
        
        You sit heavily, glad to be off your feet at last. The cube is hard, but faintly warm to the touch.
        
    *selectable_if (fighting_style = 3) #Pull up a 'chair' with my tendrils.
        *set rel_wyrd +2
        @{speciality You swing your tendrils underneath yourself and perch upon them.|With your body as outsized as it is, that's not the easiest task, but pumping a little more vigour into your more normally proportioned tendril gives it enough strength to support your weight.|You have to concentrate pretty hard on pumping up your tendrils, what with the added weight of your carapace, but you get them sturdy enough to support your weight.} The corner of Wyrd's mouth twitches up.

*if mc_health > 1
    "Lemme take a look at those injuries," Wyrd moves a little closer to you. "Don't worry, I'm a doctor."
    *choice
        #Accept gratefully.
            *set rel_wyrd +2
            "I'd appreciate that, thank you."
            
            Wyrd smiles. "Awesome."
            
            *label treatment
            *set treatment 2
            *set doctormal 2
            Walking to your side, Wyrd pulls a small pouch out of their jacket and from within, a roll of bandages and a spray cannister. Calmly and professionally, they disinfect your injuries and get you bandaged up. The process is relatively painless and completed efficiently. Maybe Wyrd isn't actually a doctor, but they do at least know what they're doing.
            
            "All done."
            
            You give Wyrd a quick nod of thanks, and they return to their leaning post.
            *goto firstthingsfirst
        #Accept reluctantly.
            *set rel_wyrd +2
            "Okay…" you murmur.
            
            Wyrd smirks. "Hey, I'll give you a lollipop if you're a good patient."
            
            *goto treatment
        #Gesture at my unusual body. "Can you manage with this?"
            *set rel_wyrd +2
            "Oh absolutely. I'm good with strange physiology. Expert, even."
            
            They seem genuine enough. You hesitate, then nod.
            
            *goto treatment
        #"Are you?" I'm sceptical.
            *set rel_wyrd -2
            Wyrd grins. "I know, I don't look like the type."
            *choice
                #I hesitate, but I should really get my wounds looked at.
                    *set rel_wyrd +2
                    "Well… I'm hurt after all."
                    
                    Wyrd nods easily. "Just relax and I'll take care of it."
                    
                    *goto treatment
                #No they do not. I turn them down.
                    "No thanks."
                    
                    *goto treatreject
        #I shake my head.
            *label treatreject
            *set rel_wyrd -2
            *set treatment 3
            *set doctormal 3
            Wyrd pauses, shrugs, and then returns to their leaning post. "Suit yourself."
            *goto firstthingsfirst
    
*else
    *label firstthingsfirst
    
    "Firstly, I'd like to thank you for your help," says Architect. "Our operation would have been considerably more difficult without your intervention." He's laid the briefcase across his lap. One hand rests protectively atop it.

*choice
    #I nod and wait for him to continue.
        *if expressive > 35
            *set expressive -3
        *else
            *set expressive -1
            
        *set rel_architect +1
        Architect's head inclines by a fraction of an inch.
    #"I think it could have gone better."
        *if (surpass_fight = 3) or (mc_health > 1)
            *set rel_architect +1
            "Yes, perhaps, but we all left under our own power, and the objective is secure." Architect leans forward. "Frankly, given you joined partway through, the outcome could have been considerably worse."
        *else
            Architect regards you with faceless scrutiny. "All things considered, I feel this was a remarkable result. Most operations would not proceed so smoothly with the abrupt addition of a third party."
    #"You're welcome," I say, with a little flair.
        *if expressive < 65
            *set expressive +3
            
        *else
            *set expressive +1
            
        Architect nods acknowledgement. Wyrd laughs softly.
    #"I can't believe you threatened a civilian like that."
        *if brutal = 0
            *set rel_wyrd +2
            *set rel_architect +1
            "Although it wouldn't be my first choice, such measures are occasionally necessary." Architect's voice is calm and level.
            
            "You don't think you could have helped without endangering someone's life?"
            
            "Perhaps, perhaps not," he replies, in a tone indicating that either way, he's done talking about this.
            
        *else
            *set rel_architect -2
            Architect turns his faceless scrutiny upon you. "I am a little surprised to hear that, given your methods during the fight."
            
            "That was different," you assert.
            
            "Hm."

*page_break Architect continues.

"Before we go on I have an important question. Why exactly did you assist us?"

This is it. You think back to sleepless nights, day after day of relentless instruction, testing, punishment, instruction.

You know your answer.

*choice
    #"I want to bring down the system," I lie.
        *set rel_architect +5
        *set motive 1
        "Do you now."
        
        You're uncertain of how to read Architect's tone and straighten up defiantly. "What?" you challenge, keeping to script. "Is that a problem?"
        
        Architect huffs softly. It takes a moment to realise that he just laughed. "No. Quite the opposite."
        
        "You're speaking Architect's language," adds Wyrd, giving you a lopsided grin. "Careful, you might set off a rant."
        
        "You say that as if I make speeches at the drop of a hat," protests Architect. Wyrd's expression turns knowing. "Wyrd!"
        *fake_choice
            #This is different. Are they more comfortable around me?
                That can only be to your benefit, right?
            #They both seem to believe me. Good.
                *set instinctive -1
                That's what matters.
            #The teasing is a good sign. I feel less tense now.
                *set expressive +1
                The atmosphere feels lighter already.
                
        *goto motiveset
    #"I'm just sick of getting kicked around by heroes," I lie.
        *set rel_architect +2
        *set rel_wyrd +2
        *set motive 2
        Architect and Wyrd exchange a significant glance.
        
        "I can understand that," says Architect after a moment.
        
        "Same here. You're in good company," Wyrd adds.
        *goto motiveset
    #"I was hoping to make some quick cash," I lie.
        *set rel_architect -1
        *set rel_wyrd -1
        *set motive 3
        "Ah, a mercenary." Architect's tone is flat. 
        
        You shrug, keeping to script. "I could waste my life in a 9-5 or following orders like a good parahuman, or I could use my powers in a way that actually benefits me."
        
        Wyrd laughs. "Can't fault you that! At the end of the day, we're all trying to use what we have to get what we want, right?"
        
        Architect's blank regard bores into you as he answers. "Indeed."
        *goto motiveset
    #"My reasons are my own," I lie.
        *set rel_wyrd +4
        *set rel_architect +1
        *set motive 4
        "Mysterious," Wyrd stage whispers.
        
        "Quiet, Wyrd." Architect's reprimand has no heat, and his companion smirks. Architect goes on. "I understand. Mutual trust takes time. Perhaps we can all be more candid in the future."
        *goto motiveset

*label motiveset

The room falls silent. You look between them both, glad of your power's inherent poker face. You think—hope—that your explanation suits them. You can barely bring yourself to speculate about the consequences of failure.

After an eternity, Architect speaks. "Regardless, I believe our cooperation may have a future." He glances at your surroundings. "However, this is neither the time nor place for such a discussion. If you're amenable, let us reconvene tomorrow in a safer location."

Relief sweeps through you, loosening the tightness in your chest. The offer is almost as much as you could have hoped for at this stage.
*fake_choice
    #Agree enthusiastically.
        *if expressive < 40
            *set rel_wyrd +2
            *set expressive +3
            "Yes, I'd fantastic—uh, that would love—" you trip over your words.
            
            Wyrd laughs with unconcealed delight. "So there's an excitable side under that stoic shell after all."
            
            "Behave, Wyrd."
            
            "Don't I always?"
            
            "No."
            
            Wyrd just laughs again.
            
        *else
            *set expressive + 5
            *set rel_architect +2
            "That would be fantastic. I'd love to," you reply immediately, allowing your emotions to shine freely.
            
            "Excellent," says Architect, a little warmer than he's been to this point.
            
            "Something about a beautiful friendship," Wyrd quips.
            
    #Agree, but play it cool.
        *if expressive > 60
            *set rel_architect +2
            *set expressive -3
            "I'm willing to talk it over. I guess we'll see," you reply, projecting calm.
            
            There's a pause, and then Architect responds, a faint note of amusement in his voice. "I can tell you're the emotional type. There's no need to cover it up."
            
            "Huh?" you blurt before you can stop yourself, then realise that you were concentrating so much on keeping a level tone that your leg has been jiggling wildly this entire time, as have your tendrils@{pierced , even the wounded one.|.}
            
            "Sheesh, Architect, your formal is rubbing off on everyone. Next thing we know, it'll be black tie for all our heists."
            
            Architect does not respond. Wyrd rolls their eyes, smirking.
            
        *else
            *set rel_wyrd +2
            *set expressive -5
            "We'll see," you reply. "I'm not promising anything."
            
            "Look at you all aloof." Wyrd speaks without rancour, and appears genuinely entertained. You nod coolly.
            
*page_break

"It's settled then," says Architect. "Meet us at noon tomorrow. I'll tell you the location." He rattles off an address that you vaguely recognise, and you do your best to commit it to memory. "I hope to see you there."

You nod.

Wyrd shifts from foot to foot. "Architect. We should split."

"Agreed." Architect addresses you. "It would be less conspicuous to leave separately."

He has a point, and speaking of conspicuous, you ought to tone down your powers before taking a stroll through the streets. You step towards the exit, ensuring you have plenty of space.

Here you go again.

*page_break Focus inward.

*if speciality =1
    Concentrating on the nodes, you call them back with a compulsion they cannot ignore. Not a command, but a deep, almost primal pull on the connection you share.
    
    [i]one. whole. us.[/i]
    
    They scramble up your body, dendrites already beginning to sink into your membrane as they ascend to your shoulders. The @{nodecrushed pair |trio } reaches your head and you take a deep, steadying breath, bracing yourself.
    
    [i]whole.[/i]
    
    You shudder as they push through the covering and squirm into your mouth. You feel your throat bulging and do your level best not to gag, choke, or vomit. Mercifully, you cease to feel their senses as they re-enter you one after the other.
    
    That doesn't spare you the quaking spasms that wrack your entire frame. You double over, mouth and chin wet with ichor. A dizzying, muddled array of impressions, feelings, and proto-memories swamps your mind as the nodes' experiences—and biomasses—meld back into your own.
    
    "Absolutely gross," says Wyrd, with relish.
    *fake_choice
        #This will pass. This will pass. This will pass.
            You repeat the mantra to yourself over and over again.
            
        #I don't have the energy to reply.
            Every spare ounce is dedicated to willing your wobbling legs to remain upright.
            
        #Flip them off.
            *set rel_wyrd +1
            *set expressive +3
            You weakly thrust your middle finger at them. Wyrd snickers.
            
    Gradually, the overwhelming flood slows to more of a trickle. Present, but manageable. Somewhere within you, the nodes wriggle, squirm, and subside.
    *goto donepowers
    
*elseif speciality =2
    You grimace as your awareness of your misshapen, mismatched body grows more and more acute. The weight hangs incorrectly. The air doesn't travel to your lungs as it should. Even the blood pumping through your veins takes a disjointed, discordant course.
    
    Though the experience is unpleasant, to reach this state is a matter of willing change and allowing it to happen. The reverse process is far less straightforward. In spite of your best efforts, there's only one method with which you've found success: dismantling the mutations piece by painstaking piece.
    
    The maw-tendril is first. You exert your power like a clenched muscle, feeling the limb compress. You maintain focus all the while, knowing that if you slacken, it'll simply revert to the prior size. As it reaches its regular size, you spare part of your concentration to hold it in that form, and then move towards the actual maw. One after the other, its teeth retract, the mouth merging back into a singular tendril.
    
    Once the tendril is back entirely to normal, you pause a moment, marshalling your power to pin it in place.
    
    And isn't that truthfully the toll of these powers? The constant, endless necessity of keeping control, lest they explode to life, twisting your body unimaginably.
    
    "Impressive," says Wyrd, looking on with an admiring eye.
    *fake_choice
        #Ignore them.
            They don't understand. They can't understand. There's no point engaging.
        #I snap at them.
            "Keep it to yourself," you growl.
            
            Wyrd shrugs. "I meant it, but sure."
        #A nod is the most I can manage.
            *set rel_wyrd +1
            Something in their expression changes at the weak gesture. You can't place it.
            
    From the tendril, you go to your distorted torso. From there, the extra eyes on your body. The particularly huge one on your head. Your misshapen, muzzlelike skull.

    Finally, your massive arm and its talons. You clench your jaw, willing the oily claws to reshape back into hands. Fingers.
    *goto donepowers

*else
    The moment you turn your attention to your carapace, all the sensations resurface. Skin on carapace. Carapace on skin. You grit your teeth.
    
    At least you'll have a reprieve now. There's even the slender consolation that you won't need to keep your relief from your face; these powers have perks. Mild ones.
    
    You flex slowly and steadily, feeling the carapace moving with you. Gradually it begins to soften, break down, retract, and reabsorb. Thankfully, this side of the experience isn't nearly as uncomfortable as the reverse.
    
    *if ((injurydesc = 3) or (injurydesc = 4))
        The process doesn't completely alleviate the damage dealt by Surpass earlier. You've still got some recovery ahead of you.
    
    "That's pretty cool," says Wyrd, looking on with interest.
    *fake_choice
        #"Easy for you to say," I mutter.
            Wyrd shrugs. "Sure. Doesn't mean I'm wrong."
            
            You shake your head, lacking the energy to argue.
        #"Trust me, it's not."
            They give a laid back shrug. "You'd know better than me."
        #I muster a weak smile.
            *set rel_wyrd +1
            You can't manage much more than that. Still, something softens in Wyrd's expression.
            
    After a minute or two of firm focus, the shell has very nearly reverted to your normal membrane, the weight no longer pressing upon your shoulders.
    
    A little more concentration. A little more willpower.
    *goto donepowers
    
*label donepowers
And at long last, you're done.

You exhale raggedly.
*fake_choice
    #I wish my power was easier to handle.
        *set content +1
        Your power is great when it's not piledriving your mental state into the ground and demanding huge portions of your focus and overall cognitive load.
    #I wish I had a different power.
        *set trade +1
        Powers? Cool. These powers? Not cool.
    #I hate having powers.
        *set hate +1
        You never asked for them or wanted them. Often, you think that you wouldn't even trade your power for another.
        
Superpowers. Every kid's dream. Brightly costumed and larger-than-life heroes and villains doing battle. The forces of good and evil, clashing live on television.

Good and evil. Sure.

Dreams… you doubt any kid ever dreamed of getting powers like yours. You sure as hell didn't.

Ugh. Maybe your perspective on them is just skewed by their origins. Your circumstances. They aren't exactly—

"You gonna be good? You looked unsteady for a sec." Wyrd's voice pulls you out of it.

Right. Right. You can't lose focus now.
*fake_choice
    #"I'll manage."
    #"Don't worry about me."
    #I nod.
        *set expressive -1
        
"Alrighty, if you say so."

Time to get moving. Divested of @{speciality the nodes|your mutations|your carapace}, you proceed towards the exit.

Architect's voice catches you in the doorway. "Ah, one final matter before you leave." You halt, glancing back over your shoulder. Architect's hands are folded primly over the briefcase. "If you're willing, I feel it would be beneficial for tomorrow's rendezvous to be maskless. In my experience, that helps considerably when establishing a rapport."

It's also much harder to stab each other in the back when everyone knows everyone else's face. Mutually assured destruction. Something Architect's well aware of, even if he isn't stating it directly.

As for you, when it comes to meeting them tomorrow unmasked…

*choice
    #I hate that, but I agree because I must.
        Great.
        
        You knew this was most likely coming, but… great.
        
        *if expressive > 60
            It's a little effort to swallow down your antipathy, and you resort to a simple nod, lest your voice betrays your frustration.
            
        *else
            Swallowing down your antipathy, you answer. "Sure."
            
        More unwelcome reminders.
        *fake_choice
            #It rankles me, having no choice.
                *set seethe +1
            #Revealing my identity bothers me.
                *set loyal +1
    #I'm indifferent, and agree because I have to.
        Really it doesn't matter to you either way, which is just as well because the decision isn't in your hands.
        
        "No problem."
        
        Honestly…
        *fake_choice
            #It's not worth getting frustrated about.
                *set seethe +1
            #Why bother caring in the first place?
                *set break +1
    #I have to agree, but at least I like the idea anyway.
        Your lack of agency is softened just a little when you'd have taken the same path regardless.
        
        Plus…
        *fake_choice
            #It's better when I don't have to think about things.
                *set break +1
            #Sometimes, it's important to look for silver linings.
                *set loyal +1

*achieve firstimpressions
"Excellent," says Architect. "See you tomorrow then."

Raising a hand, you step through the door and proceed to leave the building.

No heroes await to seize you outside, so after a brief check for any gawkers, you dart into the nearest alleyway. One final check of your surroundings, and, content that you're in the clear, you turn your concentration to you power for what will hopefully be the day's final occasion.

Your tendrils withdraw and your membrane melts away. For the first time in hours, air touches your face. Your [i]actual[/i] face.
*fake_choice
    #I can finally breathe again.
        You take a long moment to savour the sensation, eyes closed.
        
        Then, feeling recentred, you move.
    #No time to dawdle.
        A brisk once over with your power to confirm you didn't miss anything, and you set off. Relaxation later.
        
Breaking into a brisk trot, you begin making your way through the streets of Alderbrook, doing your best not to look overly suspicious. Today isn't over until you're safely back at what passes for home. That said, you're fairly sure you're in the clear when it comes to pursuit, and even if one Glory Hound or another was to sniff you out, how would they identify you? There's no trace of the membrane on your body and your shabby, second hand clothes certainly aren't a costume.

*if instinctive > 60
    You allow your feet to dictate your path, taking this street or that turning depending on what feels right in the moment. Gradually, your surroundings become more familiar.
    
*elseif instinctive > 45
    You have to spend some time studying street signs and looking out for landmarks, but you get yourself headed in the right direction eventually.
    
*else
    Consulting your mental map of town, you slot your location into it as best you can and proceed from there. Fortunately, your navigation is good and soon enough, you're in more familiar surroundings.
    
There's still no sign of anyone on your tail as you approach your destination. The neighbourhood with Architect's safehouse may have been run down, but Wesson Parks is derelict. Few services, fewer businesses, and zero law enforcement.

*page_break

The Parks happen to be pretty quiet. Any honest residents leave during the day to work someplace less condemned, and the dishonest ones have better things to do than shake down the type of people who live in the Parks. What would they have worth stealing?

In short, a great place to lie low. Not so much to live.

Turning a corner, you clap eyes upon an abandoned industrial building. Here you are.

*page_break Home sweet home.

The building's fence is no barrier—quite literally, given the plethora of holes in it—and you make your way inside with ease. Within, surrounded by corroded machinery, metal crates, and junk, is your humble abode.

A single rusty shipping container.

Making your way over, you brush the container's side with your fingertips. 'A T' and 'IN ST ES' read two faded words, most of their letters flaked away and lost. You've wondered, once or twice, what contents it originally carried. Rounding the container's corner, you reach your home's entrance, which is to say the pair of corrugated steel doors.

Inspecting the padlock, you find it intact. Not that there's much of anything worth stealing in there, nor that the meagre lock would deter a persistent thief. Still, good to know that what little you have remains secure.

Unlocking the padlock and unlatching the various clamps on the doors, you pull them open and are greeted with the sights of your own little slice of heaven.
*fake_choice
    #I've made the best of a bad situation.
        *set seethe +1
        *set livingconditions 3
        It's good to have your own space, as meagre as that space may be, and you've done what you can with your limited resources.
        
        Sooner or later, home and privacy alike will be snatched away from you, so… you'd rather enjoy this while it lasts.
    #I haven't exactly done much with the place.
        *set loyal +1
        *set livingconditions 2
        You don't have much—or anything—in the way of spare cash laying around and you have other priorities to worry about. You try to keep your environment liveable, but in the grand scheme of things you aren't going to stay here all that long.
    #Why bother trying to improve on something this awful?
        *set break +1
        *set livingconditions 1
        At the end of the day, you live in a shipping container, and no amount of DIY home improvement is going to turn it into a dream house.
        
        It's just yet another experience to endure. At least this particular hardship will be temporary.

A single mattress on the floor. A@{livingconditions  haphazard pile of clothes| solitary clothes rail|n incredibly battered clothes drawer}. A free-standing lamp. A @{livingconditions cardboard box passing for a table. Three more for storage; not that there's anything much to store.|a small wooden crate serving as a table. A couple of grocery crates for storage.|three-legged coffee table you rescued from the sidewalk. A collection of mismatched boxes and crates for storage.}

Truly, you're living the high life.

*if treatment = 3
    Shutting and securing the doors behind you in order to enjoy your daily dose of claustrophobia, you sit down heavily on the floor. Your injuries are really catching up to you now. Maybe letting Wyrd take a look wouldn't have been the worst idea—but. No. You had your reasons. Grabbing a bandage roll from your @{livingconditions not-actually-a-table|not-actually-a-table|table}, you haphazardly patch yourself up. It'll do for now, and you powers give you a leg up with healing.
    
*else
    Shutting and securing the doors behind you in order to enjoy your daily dose of claustrophobia, you sit down heavily on the floor. What a damn day. Still, through a combination of luck and skill, you made it out intact. That's worth something.
    
After taking a quiet moment of nothing, you sigh and drag yourself over to your bed, flopping onto your back. It's essential to be rested for tomorrow and while it's barely edging into evening, you're completely exhausted. 

There's something ironic about finally having time for yourself and absolutely zero energy to spend it.

At least nobody's expecting a status report until tomorrow.

All in all…
*fake_choice
    #That could have gone worse.
        You're lying here, the first task of many successfully completed. There were innumerable ways for today to go wrong, and you successfully dodged almost all of them.
        
        So far as you can tell. Maybe the piper is on the way to collect.
    #Mask fights are nuts.
        You thought your training had prepared you, and that's true to an extent… since without training, you would have got absolutely pulverised today. As opposed to @{surpass_fight moderately|only minorly|just mostly} pulverised.
        
        It's still sobering. There's likely to be a great many fights in your future. You'll have to ensure you're ready.
    *selectable_if (surpass_fight = 2) #Look at me, fighting Surpass to a draw.
        Surpass is definitively the last member of the Glory Hounds you wanted to see today, and you still managed to take her on. You can't say you beat her, but neither did you lose.
        
        It's a heck of a shot to the self-esteem… which you have to hope will be enough of a boost for next go around, because Surpass is absolutely the kind of hero who'll take that result as a challenge.
    #I should really settle on a mask name.
        Luckily, nobody asked you for one today, but if you keep being indecisive, the media or heroes are going to take the decision out of your hands.
        
        You really don't want to end up being dubbed Captain Tentacles or something.
    #I wonder what Architect and Wyrd are like, underneath it all.
        Everyone was a performer today, even you. Wearing a mask is as much about donning a persona as it is concealing an identity. Arguably, the overlap is almost total. You got a small glimpse into Architect and Wyrd at their safehouse, but tomorrow will be far more telling.
        
        …and they'll be measuring you up, just as you'll measure them.
        
Fatigue crowds you ever closer, and you muzzily shake your head as a slow ache begins to pulse in your temples.

Alright. Thinking time is officially over. You drag @{livingconditions a moth-eaten blanket|a cheap, nondescript blanket|the actually halfway-decent duvet you managed to scrounge} over your body, and let your head fall back onto the mattress with a thump.
        
You hope more than anything that you can simply fall into a restful, dreamless sleep.

It's neither.

*finish Remember.